File Coverage

blib/lib/Mojolicious/Plugin/Captcha/reCAPTCHA.pm

Criterion	Covered	Total	%
statement	15	54	27.7
branch	0	12	0.0
condition	0	8	0.0
subroutine	5	15	33.3
pod	1	1	100.0
total	21	90	23.3

package Mojolicious::Plugin::Captcha::reCAPTCHA;

# ABSTRACT: use Captcha::reCAPTCHA in Mojolicious apps

use strict;
use warnings;

use Mojo::Base 'Mojolicious::Plugin';
use Mojo::ByteStream;
use Captcha::reCAPTCHA;

our $VERSION = 0.05;
$VERSION = eval $VERSION;

sub register {
    my $self = shift;
    my $app  = shift;
    my $conf = shift || {};

    $app->log->debug("Usage of Mojolicious::Plugin::Captcha::reCAPTCHA is deprecated; you should consider switching to Mojolicious::Plugin::ReCAPTCHAv2");

    die ref($self), ": need private and public key\n"
        unless $conf->{private_key} and $conf->{public_key};

    $app->attr(
        'recaptcha_obj' => sub {
            Captcha::reCAPTCHA->new;
        },
    );

    $app->attr( recaptcha_private_key => sub { $conf->{private_key} } );
    $app->attr( recaptcha_public_key  => sub { $conf->{public_key} } );
    $app->attr( recaptcha_use_ssl     => sub { $conf->{use_ssl} } );
    $app->attr( recaptcha_options     => sub { $conf->{options} } );

    $app->helper( recaptcha => sub { return shift->app->recaptcha_obj } );
    $app->helper(
        use_recaptcha => sub {
            my $self = shift;
            $self->stash( recaptcha_html => $self->recaptcha_html(@_) );
            return;
        }
    );
    $app->helper(
        recaptcha_html => sub {
            my ( $self, $err, $use_ssl, $options ) = @_;
            if ( !defined $use_ssl ) {
                if ( defined $self->app->recaptcha_use_ssl ) {
                    $use_ssl = $self->app->recaptcha_use_ssl;
                }
                elsif (    $self->req->url->base->scheme eq 'https'
                        or $self->req->headers->header('X-Forwarded-Protocol') eq 'https' )
                {
                    $use_ssl = 1;
                }
                else {
                    $use_ssl = undef;
                }
            }
            if ( !defined $options ) {
                $options = $self->app->recaptcha_options;
            }
            return Mojo::ByteStream->new(
				$self->recaptcha->get_html( $self->app->recaptcha_public_key, $err, $use_ssl, $options )
			);
        }
    );
    $app->helper(
        validate_recaptcha => sub {
            my ( $self, $params ) = @_;

            my $result = $self->recaptcha->check_answer( $self->app->recaptcha_private_key,
                                                         $self->tx->remote_address,
                                                         $params->{recaptcha_challenge_field},
                                                         $params->{recaptcha_response_field},
            );

            if ( !$result->{is_valid} ) {
                $self->stash( recaptcha_error => $result->{error} );
                return 0;
            }
            return 1;
        }
    );

    return;
} ## end sub register

1;

__END__