File Coverage

blib/lib/Mojolicious/Plugin/CachePurge.pm

Criterion	Covered	Total	%
statement	12	39	30.7
branch	2	10	20.0
condition	0	3	0.0
subroutine	3	12	25.0
pod	1	1	100.0
total	18	65	27.6

package Mojolicious::Plugin::CachePurge;
use Mojo::Base 'Mojolicious::Plugin';
use Mojo::URL;

our $VERSION = '0.01';

has 'ua' => sub { Mojo::UserAgent->new; };

sub register {
    my ( $self, $app, $conf ) = @_;

    if ( defined( $conf->{baseurl} ) ) {
        $app->log->error("CachePurge: Can not parse baseurl as url, aborting")
          unless ( $self->{'baseurl'} = Mojo::URL->new( $conf->{'baseurl'} ) );
    }
    else {
        $app->log->error("CachePurge: No baseurl configured, aborting");
    }

    if ( $self->{'baseurl'} ) {
        $self->_add_log_hooks($app);
        $app->helper( 'cache_purge' => sub { $self->_purge(@_) } );
    }
    else {
        $app->helper( 'cache_purge' =>
              sub { $app->log->debug('CachePurge: inactive, config error') } );
    }

    return $self;
}

sub _add_log_hooks {
    my ( $self, $app ) = @_;

    $self->ua->on(
        start => sub {
            my ( $ua, $tx ) = @_;
            my $msg =
                "CachePurge: request, method="
              . $tx->req->method
              . ", url="
              . $tx->req->url;
            $app->log->debug($msg);
        },
        error => sub {
            my ( $ua, $err ) = @_;
            $app->log->error( "CachePurge: " . $err );
        }
    );

}

sub _purge {
    my ( $self, $c, $args, $cb ) = @_;

    # We may get a callback, but no args. It will be here as $args, so
    # we move it.
    if (ref $args eq 'CODE') {
        $cb = $args;
        undef $args;
    }

    my $purge_path = $args->{'path'} ||= $c->req->url->path;

    my $purge_url = Mojo::URL->new( $self->{'baseurl'} )->path($purge_path);

    Mojo::IOLoop->delay(
        sub {
            my ($delay) = @_;
            my $tx = $self->ua->build_tx( PURGE => $purge_url );
            $self->ua->start( $tx => $delay->begin );
        },

        # log response
        sub {
            my ( $delay, $tx ) = @_;
            $c->app->log->debug( "CachePurge: response, url="
                  . $tx->req->url
                  . ", code="
                  . $tx->res->code );
            $delay->pass($tx);
        },

        # handle callback, if any
        sub {
            my ( $delay, $tx ) = @_;
            $self->$cb($tx) if ($cb);
        }
    );
}

1;
__END__