File Coverage

lib/Mojolicious/Plugin/CHI.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	17	20	85.0
condition	9	14	64.2
subroutine	7	7	100.0
pod	1	1	100.0
total	77	85	90.5

package Mojolicious::Plugin::CHI;
use Mojo::Base 'Mojolicious::Plugin';
use Scalar::Util 'weaken';
use CHI;

our $VERSION = '0.18';

# Register Plugin
sub register {
  my ($plugin, $mojo, $param) = @_;

  # Load parameter from config file
  if (my $config_param = $mojo->config('CHI')) {
    $param = { %$param, %$config_param };
  };

  # Hash of cache handles
  my $caches;

  # Add 'chi_handles' attribute
  # Necessary for multiple cache registrations
  unless ($mojo->can('chi_handles')) {
    $mojo->attr(
      chi_handles => sub {
        return ($caches //= {});
      }
    );
  }

  # Get caches from application
  else {
    $caches = $mojo->chi_handles;
  };

  # Support classes
  my $chi_class = delete $param->{chi_class} // 'CHI';

  # Support namespaces
  my $ns = delete $param->{namespaces} // 1;

  # Create log callback for CHI Logging
  my $log = $mojo->log;
  weaken $log;
  my $log_ref = sub {
    $log->warn( shift ) if defined $log;
  };

  # Loop through all caches
  foreach my $name (keys %$param) {
    my $cache_param = $param->{$name};

    next unless ref $cache_param && ref $cache_param eq 'HASH';

    # Already exists
    if (exists $caches->{$name}) {
      $mojo->log->warn(qq{Multiple attempts to establish cache "$name"});
      next;
    };

    # Set namespace
    if ($ns) {
      $cache_param->{namespace} //= $name unless $name eq 'default';
    };

    # Get CHI handle
    my $cache = $chi_class->new(

      # Set logging routines
      on_get_error => $log_ref,
      on_set_error => $log_ref,

      %$cache_param
    );

    # No succesful creation
    $mojo->log->warn(qq{Unable to create cache handle "$name"}) unless $cache;

    # Store CHI handle
    $caches->{$name} = $cache;
  };

  # Only establish once
  unless (exists $mojo->renderer->helpers->{chi}) {

    # Add 'chi' command
    push @{$mojo->commands->namespaces}, __PACKAGE__;

    # Add 'chi' helper
    $mojo->helper(
      chi => sub {
        my $c = shift;
        my $name = shift // 'default';

        my $cache = $caches->{$name};

        # Cache unknown
        $c->app->log->warn(qq{Unknown cache handle "$name"}) unless $cache;

        # Return cache
        return $cache;
      }
    );
  };
};


1;


__END__