File Coverage

lib/Mojolicious/Plugin/CHI/chi.pm

Criterion	Covered	Total	%
statement	40	43	93.0
branch	18	24	75.0
condition	13	18	72.2
subroutine	5	5	100.0
pod	1	1	100.0
total	77	91	84.6

package Mojolicious::Plugin::CHI::chi;
use Mojo::Base 'Mojolicious::Command';
use Mojo::Util qw/tablify quote/;

use Getopt::Long qw/GetOptions :config no_auto_abbrev no_ignore_case/;

has description => 'Interact with CHI caches';
has usage       => sub { shift->extract_usage };

sub _unknown {
  return 'Unknown cache handle ' . quote($_[0]) . ".\n\n"
};

# Run chi
sub run {
  my $self = shift;

  my $command = shift;

  print $self->usage and return unless $command;

  # Get the application
  my $app = $self->app;
  my $log = $app->log;

  # List all associated caches
  if ($command eq 'list') {
    my $caches = $app->chi_handles;
    my @list;
    foreach (sort { lc($a) cmp lc($b) } keys %$caches) {
      push(@list, [$_, ($caches->{$_}->short_driver_name || '[UNKNOWN]')]);
    };
    print tablify \@list;
    return 1;
  }

  # Purge or clear a cache
  elsif ($command eq 'purge' || $command eq 'clear') {
    my $cache = shift || 'default';

    my $chi = $app->chi($cache);

    # Cache is unknown
    print _unknown($cache) and return unless $chi;

    # Do not modify non-persistant in-process caches!
    if ($chi->short_driver_name =~ /^(?:Raw)?Memory$/) {
      $log->warn("You are trying to $command a ".
                   $chi->short_driver_name .
                   '-Cache');
    };

    $chi->$command();

    # Purge or clear cache
    print qq{Cache "$cache" was } . $command .
      ($command eq 'clear' ? 'ed' : 'd') . ".\n\n";

    return 1;
  }

  # Remove or expire a key
  elsif ($command eq 'remove' || $command eq 'expire') {
    my $key   = pop(@_);
    my $cache = shift || 'default';

    if ($key) {

      my $chi = $app->chi($cache);

      # Cache is unknown
      print _unknown($cache) and return unless $chi;;

      # Do not modify non-persistant in-process caches!
      if ($chi->short_driver_name =~ /^(?:Raw)?Memory$/) {
        $log->warn("You are trying to $command " .
                     'a key from a '.
                     $chi->short_driver_name .
                     '-Cache');
      };

      # Remove or expire key
      if ($chi->$command($key)) {
        print qq{Key "$key" from cache "$cache" was } . $command . "d.\n\n";
      }

      # Not successful
      else {
        print 'Unable to ' . $command .
          qq{ key "$key" from cache "$cache".\n\n};
      };

      return 1;
    };
  };

  # Unknown command
  print $self->usage and return;
};


1;


__END__