File Coverage

blib/lib/Mojolicious/Plugin/BasicAuth.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	9	10	90.0
condition	9	10	90.0
subroutine	8	8	100.0
pod	1	1	100.0
total	58	60	96.6

package Mojolicious::Plugin::BasicAuth;

use strict;
use warnings;
use Mojo::ByteStream;

our $VERSION = '0.08';

use base 'Mojolicious::Plugin';

sub register {
    my ($plugin, $app) = @_;

    $app->renderer->add_helper(
        basic_auth => sub {
            my $self = shift;

            #
            # Sent Credentials
            my $auth = $self->req->url->to_abs->userinfo || '';

            # Required credentials
            my ($realm, $password, $username) = $plugin->_expected_auth(@_);
            my $callback = $password if ref $password eq 'CODE';

            # No credentials entered
            return $plugin->_password_prompt($self, $realm)
              if !$auth and !$callback;

            # Verification within callback
            return 1 if $callback and $callback->(split /:/, $auth, 2);

            # Verified with realm => username => password syntax
            return 1 if $auth eq ($username || '') . ":$password";

            # Not verified
            return $plugin->_password_prompt($self, $realm);
        }
    );
}

sub _expected_auth {
    my $self  = shift;
    my $realm = shift;

    return @$realm{qw/ realm password username /} if ref $realm eq "HASH";

    # realm, pass, user || realm, pass, undef || realm, callback
    return $realm, reverse @_;
}

sub _password_prompt {
    my ($self, $c, $realm) = @_;

    $c->res->headers->www_authenticate("Basic realm=$realm");
    $c->res->code(401);
    $c->rendered;

    return;
}

1;
__END__