File Coverage

blib/lib/Mojolicious/Plugin/AssetPack/Pipe/Combine.pm

Criterion	Covered	Total	%
statement	10	23	43.4
branch	1	10	10.0
condition			n/a
subroutine	3	4	75.0
pod	1	1	100.0
total	15	38	39.4

package Mojolicious::Plugin::AssetPack::Pipe::Combine;
use Mojo::Base 'Mojolicious::Plugin::AssetPack::Pipe';
use Mojolicious::Plugin::AssetPack::Util qw(checksum diag DEBUG);

has enabled => sub { shift->assetpack->minify };

sub process {
  my ($self, $assets) = @_;
  my $combine = Mojo::Collection->new;
  my @other;

  return unless $self->enabled;

  for my $asset (@$assets) {
    if ($asset->isa('Mojolicious::Plugin::AssetPack::Asset::Null')) {
      next;
    }
    elsif (grep { $asset->format eq $_ } qw(css js)) {
      push @$combine, $asset;
    }
    else {
      push @other, $asset;
    }
  }

  # preserve assets such as images and font files
  @$assets = @other;

  if (@$combine) {
    my $checksum = checksum $combine->map('checksum')->join(':');
    my $content = $combine->map('content')->map(sub { /\n$/ ? $_ : "$_\n" })->join;
    diag 'Combining assets into "%s" with checksum %s.', $self->topic, $checksum if DEBUG;
    push @$assets,
      Mojolicious::Plugin::AssetPack::Asset->new(url => $self->topic)
      ->checksum($checksum)->minified(1)->content($content);
  }
}

1;

=encoding utf8

=head1 NAME

Mojolicious::Plugin::AssetPack::Pipe::Combine - Combine multiple assets to one

=head1 DESCRIPTION

L will take a list of
assets and turn them into a single asset.

=head1 ATTRIBUTES

  $bool = $self->enabled;

Set this to false to disable combining assets into a single file. The default
value will be L.

=head1 METHODS

=head2 process

See L.

=head1 SEE ALSO

L.

=cut