File Coverage

blib/lib/Mojolicious/Plugin/JSONConfig.pm

Criterion	Covered	Total	%
statement	22	22	100.0
branch	4	6	66.6
condition	2	2	100.0
subroutine	6	6	100.0
pod	3	3	100.0
total	37	39	94.8

package Mojolicious::Plugin::JSONConfig;
use Mojo::Base 'Mojolicious::Plugin::Config';

use Mojo::JSON qw(from_json);
use Mojo::Template;

sub parse {
  my ($self, $content, $file, $conf, $app) = @_;

  my $config = eval { from_json $self->render($content, $file, $conf, $app) };
  die qq{Can't load configuration from file "$file": $@} if $@;
  die qq{Configuration file "$file" did not return a JSON object} unless ref $config eq 'HASH';

  return $config;
}

sub register { shift->SUPER::register(shift, {ext => 'json', %{shift()}}) }

sub render {
  my ($self, $content, $file, $conf, $app) = @_;

  # Application instance and helper
  my $prepend = q[no strict 'refs'; no warnings 'redefine'; my $app = shift; sub app; local *app = sub { $app };]
    . q[use Mojo::Base -strict; no warnings 'ambiguous';];

  my $mt     = Mojo::Template->new($conf->{template} // {})->name($file);
  my $output = $mt->prepend($prepend . $mt->prepend)->render($content, $app);
  return ref $output ? die $output : $output;
}

1;

=encoding utf8

=head1 NAME

Mojolicious::Plugin::JSONConfig - JSON configuration plugin

=head1 SYNOPSIS

  # myapp.json (it's just JSON with embedded Perl)
  {
    %# Just a value
    "foo": "bar",

    %# Nested data structures are fine too
    "baz": ["♥"],

    %# You have full access to the application
    "music_dir": "<%= app->home->child('music') %>"
  }

  # Mojolicious
  my $config = $app->plugin('JSONConfig');
  say $config->{foo};

  # Mojolicious::Lite
  my $config = plugin 'JSONConfig';
  say $config->{foo};

  # foo.html.ep
  %= config->{foo}

  # The configuration is available application-wide
  my $config = app->config;
  say $config->{foo};

  # Everything can be customized with options
  my $config = plugin JSONConfig => {file => '/etc/myapp.conf'};

=head1 DESCRIPTION

L is a JSON configuration plugin that preprocesses its input with L.

The application object can be accessed via C<$app> or the C function. A default configuration filename in the
application home directory will be generated from the value of L (C<$moniker.json>). You can
extend the normal configuration file C<$moniker.json> with C specific ones like C<$moniker.$mode.json>, which
will be detected automatically.

These configuration values are currently reserved:

=over 2

=item C

If this configuration value has been set in L when this plugin is loaded, it will not do anything
besides loading deployment specific plugins.

=item C

  "plugins": [{"SetUserGroup": {"user": "sri", "group": "staff"}}]

One or more deployment specific plugins that should be loaded right after this plugin has been loaded.

=back

The code of this plugin is a good example for learning to build new plugins, you're welcome to fork it.

See L for a list of plugins that are available by default.

=head1 OPTIONS

L inherits all options from L and supports the following
new ones.

=head2 template

  # Mojolicious::Lite
  plugin JSONConfig => {template => {line_start => '.'}};

Attribute values passed to L object used to preprocess configuration files.

=head1 METHODS

L inherits all methods from L and implements the
following new ones.

=head2 parse

  $plugin->parse($content, $file, $conf, $app);

Process content with L and parse it with L.

  sub parse ($self, $content, $file, $conf, $app) {
    ...
    $content = $self->render($content, $file, $conf, $app);
    ...
    return $hash;
  }

=head2 register

  my $config = $plugin->register(Mojolicious->new);
  my $config = $plugin->register(Mojolicious->new, {file => '/etc/foo.conf'});

Register plugin in L application and merge configuration.

=head2 render

  $plugin->render($content, $file, $conf, $app);

Process configuration file with L.

  sub render ($self, $content, $file, $conf, $app) {
    ...
    return $content;
  }

=head1 SEE ALSO

L, L, L.

=cut