File Coverage

blib/lib/Mojolicious/Command/Author/cpanify.pm

Criterion	Covered	Total	%
statement	16	22	72.7
branch	4	10	40.0
condition	0	2	0.0
subroutine	5	5	100.0
pod	1	1	100.0
total	26	40	65.0

package Mojolicious::Command::Author::cpanify;
use Mojo::Base 'Mojolicious::Command';

use Mojo::File qw(path);
use Mojo::Util qw(getopt);

has description => 'Upload distribution to CPAN';
has usage       => sub { shift->extract_usage };

sub run {
  my ($self, @args) = @_;

  die $self->usage unless getopt \@args,
    'p|password=s' => \(my $password = ''),
    'u|user=s'     => \(my $user     = '');
  die $self->usage unless my $file = shift @args;

  my $tx = $self->app->ua->tap(sub { $_->proxy->detect })->post(
    "https://$user:$password\@pause.perl.org/pause/authenquery" => form => {
      HIDDENNAME                        => $user,
      CAN_MULTIPART                     => 1,
      pause99_add_uri_upload            => path($file)->basename,
      SUBMIT_pause99_add_uri_httpupload => ' Upload this file from my disk ',
      pause99_add_uri_uri               => '',
      pause99_add_uri_httpupload        => {file => $file},
    }
  );

  if (my $err = $tx->error) {
    my $code = $tx->res->code // 0;
    my $msg  = $err->{message};
    if    ($code == 401) { $msg = 'Wrong username or password.' }
    elsif ($code == 409) { $msg = 'File already exists on CPAN.' }
    die qq{Problem uploading file "$file": $msg\n};
  }

  say 'Upload successful!';
}

1;

=encoding utf8

=head1 NAME

Mojolicious::Command::Author::cpanify - CPAN-ify command

=head1 SYNOPSIS

  Usage: APPLICATION cpanify [OPTIONS] [FILE]

    mojo cpanify -u sri -p secr3t Mojolicious-Plugin-MyPlugin-0.01.tar.gz

  Options:
    -h, --help                  Show this summary of available options
    -p, --password    PAUSE password
    -u, --user            PAUSE username

=head1 DESCRIPTION

L uploads files to CPAN.

This is a core command, that means it is always enabled and its code a good example for learning to build new commands,
you're welcome to fork it.

See L for a list of commands that are available by default.

=head1 ATTRIBUTES

L inherits all attributes from L and implements the
following new ones.

=head2 description

  my $description = $cpanify->description;
  $cpanify        = $cpanify->description('Foo');

Short description of this command, used for the command list.

=head2 usage

  my $usage = $cpanify->usage;
  $cpanify  = $cpanify->usage('Foo');

Usage information for this command, used for the help screen.

=head1 METHODS

L inherits all methods from L and implements the following
new ones.

=head2 run

  $cpanify->run(@ARGV);

Run this command.

=head1 SEE ALSO

L, L, L.

=cut