File Coverage

blib/lib/MojoX/Renderer/Xslate.pm

Criterion	Covered	Total	%
statement	56	58	96.5
branch	14	18	77.7
condition	4	9	44.4
subroutine	13	13	100.0
pod	1	1	100.0
total	88	99	88.8

package MojoX::Renderer::Xslate;

use strict;
use warnings;

use File::Spec ();
use Mojo::Base -base;
use Mojo::Loader qw(data_section);
use Text::Xslate ();

our $VERSION = '0.14';
$VERSION = eval $VERSION;

has 'xslate';

sub build {
    my $self = shift->SUPER::new(@_);
    $self->_init(@_);
    return sub { $self->_render(@_) };
}

sub _init {
    my ($self, %args) = @_;

    my $app = $args{mojo} || $args{app};
    my $cache_dir;
    my @path = $app->home->rel_file('templates');

    if ($app) {
        $cache_dir = $app->home->rel_file('tmp/compiled_templates');
        push @path, data_section(
            $app->renderer->classes->[0],
        );
    }
    else {
        $cache_dir = File::Spec->tmpdir;
    }

    my %config = (
        cache_dir    => $cache_dir,
        path         => \@path,
        warn_handler => sub { },
        die_handler  => sub { },
        %{$args{template_options} || {}},
    );

    $self->xslate(Text::Xslate->new(\%config));

    return $self;
}

sub _render {
    my ($self, $renderer, $c, $output, $options) = @_;

    my $name = $c->stash->{'template_name'}
        || $renderer->template_name($options);
    my %params = (%{$c->stash}, c => $c);

    my $orig_err = $@;
    my $xslate_err;

    local $@;
    eval {
        local $SIG{__DIE__} = sub { $xslate_err = shift };

        if (defined(my $inline = $options->{inline})) {
            $$output = $self->xslate->render_string($inline, \%params);
        } else {
            if (defined ($renderer->template_path($options))) {
                $c->app->log->debug(qq{Rendering template "$name"});
                $$output = $self->xslate->render($name, \%params);
            } elsif (defined (my $data_template = $renderer->get_data_template($options))) {
                $c->app->log->debug(qq{Rendering template "$name" from DATA section});
                $$output = $self->xslate->render_string($data_template, \%params);
            } else {
                $c->app->log->debug(qq{Template "$name" not found})
            }
        }
    };
    $@ = $xslate_err if $xslate_err;

    if ($@) {
        $$output = undef;
        if (    ( index( $@, 'Text::Xslate: LoadError: Cannot find \'exception.' ) < 0 )
             && ( index( $@, 'Text::Xslate: LoadError: Cannot find \'not_found.' ) < 0 )
        ) {
            die $@ unless $orig_err;
        }
    }

    return 1;   # return value needed for Mojolicious <= 6.32
}


1;

__END__