File Coverage

blib/lib/MojoX/Log/Any.pm

Criterion	Covered	Total	%
statement	29	34	85.2
branch	5	10	50.0
condition			n/a
subroutine	7	8	87.5
pod			n/a
total	41	52	78.8

package MojoX::Log::Any;
# ABSTRACT: Use the current Log::Any adapter from Mojolicious

use strict;
use warnings;

our $VERSION = '0.004';

use Log::Any;
use Log::Any::Plugin;
use Class::Load qw( is_class_loaded );
use Class::Method::Modifiers qw( install_modifier );

sub import {
  my $class = shift;
  my $caller = caller;

  my $lite = is_class_loaded( 'Mojolicious::Lite' );
  my $mojo = $caller->isa( 'Mojolicious' );

  my $log = Log::Any->get_logger(
    default_adapter => 'MojoLog',
    category => $caller,
    @_,
  );

  Log::Any::Plugin->add( 'History', size => 10 );
  Log::Any::Plugin->add( 'Format' );

  # Manually inflate nulls, since we are not doing automatic assignment
  $log->inflate_nulls if $log->isa('Log::Any::Proxy::Null');

  if ($lite) {
    # Using Mojolicious::Lite

    return if $caller->app->log->isa('Log::Any::Proxy');
    $caller->app->log( $log );
  }
  elsif ($mojo) {
    # Caller inherits from Mojolicious

    # Entirely replace Mojolicious log method, so we return a reference to
    # the Log::Any proxy instead of to Mojo::Log
    install_modifier( $caller, 'around', log => sub {
      my $orig = shift;
      my $self = shift;

      $log = $_[1] if @_ > 1;
      return $log;
    });
  }
}

1;

__END__