File Coverage

lib/MojoX/JSON/RPC/Service.pm

Criterion	Covered	Total	%
statement	30	36	83.3
branch	10	16	62.5
condition	6	8	75.0
subroutine	4	4	100.0
pod	3	3	100.0
total	53	67	79.1

package MojoX::JSON::RPC::Service;

use Mojo::Base -base;

{

    # Store rpc methods registered by register_rpc_method_names
    my $_rpcs = undef;

    sub new {
        my $class = shift;
        my $self  = $class->SUPER::new(@_);

        # make shallow copy of class level rpcs
        if ( ref $_rpcs eq 'HASH' && exists $_rpcs->{$class} ) {
            $self->{_rpcs} = { %{ $_rpcs->{$class} } };
        }
        return $self;
    }

    sub register_rpc_method_names {
        my ( $class, @methods ) = @_;

    METHOD:
        foreach my $m (@methods) {
            my $name   = $class . '::' . $m;
            my $method = eval qq|*{*$name}{CODE}|;

            if ( ref $method ne 'CODE' ) {
                Carp::croak
                    qq{register_rpc_method_names: $name not a method.};
            }
            if ( exists $_rpcs->{$class}->{$m} ) {
                Carp::croak
                    qq{register_rpc_method_names: $name already registered.};
            }
            $_rpcs->{$class}->{$m} = { method => $method, with_svc_obj => 1 };
        }

        return $class;
    }
}

sub register {
    my ( $self, $name, $sub, $options ) = @_;

    if ( !defined $name || $name eq q{} ) {
        Carp::croak 'name?';
    }
    if ( ref $sub ne 'CODE' ) {
        Carp::croak qq{name[$name] code?};
    }
    if ( exists $self->{_rpcs}->{$name} ) {
        Carp::croak qq{$name already registered};
    }

    $options ||= {};
    if ( ref $options ne 'HASH' ) {
        Carp::croak 'options?';
    }

    my %obj = ( method => $sub );
OPTION:
    foreach my $opt ( 'with_mojo_tx', 'with_svc_obj', 'with_self' ) {
        if ( !exists $options->{$opt} ) {
            next OPTION;
        }
        $obj{$opt} = $options->{$opt};
    }

    $self->{_rpcs}->{$name} = \%obj;
    return $self;
}

1;

__END__