File Coverage

blib/lib/Mojo/Transaction/HTTP/Role/Mechanize.pm

Criterion	Covered	Total	%
statement	22	22	100.0
branch	13	14	92.8
condition	7	7	100.0
subroutine	4	4	100.0
pod	1	1	100.0
total	47	48	97.9

package Mojo::Transaction::HTTP::Role::Mechanize;

use Mojo::Base -role;
use Mojo::UserAgent::Transactor;

our $VERSION = '0.04';

requires qw{error};

sub submit {
  my ($self, $selector, $overlay) = (shift);
  $overlay   = pop if @_ && ref($_[-1]) eq 'HASH';
  $selector  = shift if @_ % 2;
  $overlay ||= { @_ };
  # cannot continue from error state
  return if $self->error;
  # form from selector
  return unless defined(my $form = $self->res->dom->find('form')
    ->grep(sub { $_->at($selector || '') })->first);
  # compose ...
  $form->with_roles('Mojo::DOM::Role::Form')
    unless Role::Tiny::does_role($form, 'Mojo::DOM::Role::Form');
  # # now there is a form, rely on _form_default_submit() if we relied on $any b4.
  # $selector = undef if $any eq $selector;
  return unless (my ($method, $target, $type) =
    $form->target($selector));
  $target = $self->req->url->new($target);
  $target = $target->to_abs($self->req->url) unless $target->is_abs;
  # values from form
  my $state = $form->val($selector);
  # merge in new values of form elements
  my @keys = grep { exists $overlay->{$_} } keys %$state;
  @$state{@keys} = @$overlay{@keys};

  # build a new transaction ...
  return Mojo::UserAgent::Transactor->new->tx(
    $method => $target, {}, form => $state
    );
}


1;

=encoding utf8

=begin html



       src="https://travis-ci.com/kiwiroy/mojo-transaction-http-role-mechanize.svg?branch=master" />



       src="https://kritika.io/users/kiwiroy/repos/7509235145731088/heads/master/status.svg?type=score%2Bcoverage%2Bdeps" />



       src="https://coveralls.io/repos/github/kiwiroy/mojo-transaction-http-role-mechanize/badge.svg?branch=master" />


=end html

=head1 NAME

Mojo::Transaction::HTTP::Role::Mechanize - Mechanize Mojo a little

=head1 SYNOPSIS

  # description
  my $tx = $ua->get('/')->with_roles('+Mechanize');
  my $submit_tx = $tx->submit('#submit-id', username => 'fry');
  $ua->start($submit_tx);

=head1 DESCRIPTION

L based role to compose a form submission I<"trait"> into
L.

=head1 METHODS

L implements the following method.

=head2 submit

  # result using selector
  $submit_tx = $tx->submit('#id', username => 'fry');
  # result without selector using default submission
  $submit_tx = $tx->submit(username => 'fry');
  # passing hash, rather than list, of values
  $submit_tx = $tx->submit({username => 'fry'});
  # passing hash, rather than list, of values and a selector
  $submit_tx = $tx->submit('#id', {username => 'fry'});

Build a new L object with
L and the contents of the C with the
C<$id> and merged values.  If no selector is given, the first non-disabled
button or appropriate input element (of type button, submit, or image)
will be used for the submission.

=head1 AUTHOR

kiwiroy - Roy Storey C

=head1 CONTRIBUTORS

tekki - Rolf Stöckli C

lindleyw - William Lindley C

=head1 LICENSE

This library is free software and may be distributed under the same terms as
perl itself.

=cut