File Coverage

blib/lib/Mojo/Redfish/Client/Result.pm

Criterion	Covered	Total	%
statement	33	37	89.1
branch	11	16	68.7
condition	1	6	16.6
subroutine	9	11	81.8
pod	3	3	100.0
total	57	73	78.0

package Mojo::Redfish::Client::Result;

use Mojo::Base -base;

use Carp ();
use Mojo::Collection;
use Mojo::JSON::Pointer;
use Scalar::Util ();

my $isa = sub { Scalar::Util::blessed($_[0]) && $_[0]->isa($_[1]) };

has client => sub { Carp::croak 'client is required' }, weak => 1;
has data   => sub { Carp::croak 'data is required' };

sub get {
  my ($self, $path) = @_;
  return $self unless defined $path;
  my $target = Mojo::JSON::Pointer->new($self->data)->get($path);
  return $self->_get($target);
}

sub value {
  my ($self, $path) = @_;
  return $self->data unless defined $path;

  my $target = Mojo::JSON::Pointer->new($self->data)->get($path);

  $target = Mojo::Collection->new(@$target)
    if ref $target eq 'ARRAY';

  return $target;
}

sub TO_JSON { shift->data }

sub _get {
  my ($self, $target) = @_;
  return $target
    if $target->$isa('Mojo::Redfish::Client::Result');

  $target = Mojo::Collection->new(@$target)
    if ref $target eq 'ARRAY';

  return $target->map(sub{ $self->_get($_) })
    if $target->$isa('Mojo::Collection');

  if (ref $target eq 'HASH') {
    if (keys %$target == 1 && exists $target->{'@odata.id'}) {
      $target = $target->{'@odata.id'};
    } else {
      return $self->_clone($target);
    }
  }

  return $self->client->get($target);
}

sub _clone {
  my ($self, $data) = @_;
  $self->new(
    client => $self->client,
    data   => ($data // $self->data),
  );
}

1;

=head1 NAME

Mojo::Redfish::Client::Result

=head1 DESCRIPTION

A class to get represent the result of a request from L.
It encapsulates the returned data and facilitates walking further out in the tree by following links.

=head1 ATTRIBUTES

L inherits all of the attributes from L and implements the following new ones.

=head2 client

An instance of L, usually the one that created this object.
Required and weakened.

=head2 data

The payload result from the Redfish request.

=head1 METHODS

L inherits all of the methods from L and implements the following new ones.

=head2 get

  $result = $result->get;
  my $deeper = $result->get('/deeper/key');

Get the value of the L for the given JSON Pointer, making additional requests to follow links if needed.
Array values are upgraded to L objects and all (directly) contained values are fetched (if needed).
The result is always either a result object or a collection; use L to get a simple value out of the data by pointer.

=head2 value

Similar to L this method takes a pointer to dive into the L however the result is never fetched from the Redfish server and the value is not upgraded to a results object.
Arrays are still upgraded to L objects.

=head2 TO_JSON

Alias for L as a getter only.

=head1 SEE ALSO

=over

=item L

=back