File Coverage

blib/lib/Mojo/Promise/Role/Repeat.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	4	4	100.0
condition	3	4	75.0
subroutine	9	9	100.0
pod	2	2	100.0
total	57	58	98.2

package Mojo::Promise::Role::Repeat 0.006;

# ABSTRACT: Promise looping construct with break

use Mojo::Base -role;

sub repeat {
    my ($self, $body) = (shift, pop);
    unless (ref $self) {
	$self = $self->resolve(@_);
    }
    elsif (@_) {
	my @values = @_;
	$self = $self->then( sub { (@values, @_) });
    }
    my $done_p = $self->clone;
    my $break = sub {
	$done_p->resolve(@_);
	die $self->clone;
	# kills whatever handler we are in,
	# but because the reason is a promise,
	# does not actually reject anything,
	# any promises dependent on that handler remain unsettled,
	# and, because the passed promise is not referenced by anyone else,
	# it will NEVER be settled; that whole line of execution just stops;
        # which is not a problem here because we're skipping ahead and
	# resolving the promise at the "end" of the chain
    };
    my $again_w;
    $again_w = sub {
	 my $again = $again_w;
	 $self = $self->then(
	     sub {
		 $again->();
		 return $body->(@_) for ($break);
	     },
	     sub {
		 $done_p->reject(@_);
	     }
	 );
     };
    $again_w->();
    Scalar::Util::weaken($again_w);
    return $done_p;
};

sub repeat_catch {
    my ($self, $body) = (shift, pop);
    unless (ref $self) {
	$self = $self->reject(@_);
    }
    elsif (@_) {
	my @values = @_;
	$self = $self->catch(
	    sub { $self->clone->reject(@values, @_) }
	);
    }
    my $done_p = $self->clone;
    my $break = sub {
	$done_p->reject(@_);
	die $self->clone;
	# kill/abandon whatever handler we are in.
	# Same as for repeat()
    };
    my $again_w;
    $again_w = sub {
	my $again = $again_w;
	$self = $self->then(
	    sub {
		$done_p->resolve(@_);
	    },
	    sub {
		$again->();
		return $body->(@_) for ($break);
	    }
	);
    };
    $again_w->();
    Scalar::Util::weaken($again_w);
    return $done_p;
};

1;

__END__