File Coverage

blib/lib/Mojo/PgX/Cursor/Results.pm

Criterion	Covered	Total	%
statement	6	51	11.7
branch	0	14	0.0
condition			n/a
subroutine	2	14	14.2
pod	7	7	100.0
total	15	86	17.4

package Mojo::PgX::Cursor::Results;

require Mojo::IOLoop;
require Mojo::PgX::Cursor::Cursor;

use Time::HiRes qw(time);

use Mojo::Base -base;

has [qw(seconds_blocked fetch)];

sub array {
  my $self = shift->_fetch;
  $self->{remaining}--;
  return $self->{results}->array;
}

sub columns { shift->_results->columns }

sub cursor {
  my $self = shift;
  if (@_) {
    if ($self->{delay}) {
        $self->{delay}->wait;
    }
    $self->{cursor} = shift;
    $self->{remaining} = 0;
    delete $self->{delay};
    delete $self->{next};
    delete $self->{results};
    return $self->_load_next;
  }
  return $self->{cursor};
}

sub hash {
  my $self = shift->_fetch;
  $self->{remaining}--;
  return $self->{results}->hash;
}

sub expand {
  my $self = shift;
  $self->{expand}++;
  if ($self->{results}) {
      $self->{results}->expand;
  }
  return $self;
}

sub new {
  my $self = shift->SUPER::new(@_);
  return $self->_load_next;
}

sub rows { shift->_results->rows }

sub _fetch {
  my $self = shift;
  return $self if $self->{remaining};
  unless ($self->{next}) {
    my $start = time;
    $self->{delay}->wait;
    $self->{seconds_blocked} += time - $start;
    delete $self->{delay};
  }
  $self->{results} = delete $self->{next};
  $self->{remaining} = $self->{results}->rows;
  return $self->_load_next;
}

sub _load_next {
  my $self = shift;
  $self->{delay} = Mojo::IOLoop->delay(
    sub {
      $self->cursor->fetch($self->{fetch}, shift->begin);
    },
    sub {
      $self->{next} = $_[2];
      $self->{next}->expand if ($self->{expand});
    },
  );
  return $self;
}

sub _results {
    my $self = shift;
    return $self->{results} if $self->{results};
    return $self->_fetch->{results};
}

1;
__END__