File Coverage

blib/lib/Mojo/Log/JSON.pm

Criterion	Covered	Total	%
statement	3	3	100.0
branch			n/a
condition			n/a
subroutine	1	1	100.0
pod			n/a
total	4	4	100.0

package Mojo::Log::JSON;

use Mojo::Base 'Mojo::Log';

our $VERSION = '0.04';

has codec => sub {
    require JSON::MaybeXS;
    JSON::MaybeXS->new->indent(0)->utf8->canonical;
};

has include_level => 1;

has default_fields => sub {
    {   datetime => sub {

            my ( $sec, $min, $hour, $mday, $mon, $year ) = gmtime();
            sprintf(
                "%04d-%02d-%02d %02d:%02d:%02d",
                $year + 1900,
                $mon + 1, $mday, $hour, $min, $sec
            );
        },
    };
};

has format => sub {
    my $self = shift;

    return sub {
        my ( $time, $level, @lines ) = @_;

        my %msg = (
            (   map {

                    my $value = $self->default_fields->{$_};

                    $_ => ref $value eq 'CODE' ? $value->() : $value;

                } keys %{ $self->default_fields }
            ),

            ref $lines[0]       # data structure?
            ? %{ $lines[0] }    #  multiple keys
            : ( message => join( "\n", @lines ) ),    # single 'message' key

        );

        $msg{level} = $level if $self->include_level;

        return $self->codec->encode( \%msg ) . "\n";
    };
};

1;

__END__