File Coverage

blib/lib/Mojo/Log/Colored.pm

Criterion	Covered	Total	%
statement	16	16	100.0
branch	4	4	100.0
condition			n/a
subroutine	7	7	100.0
pod	1	1	100.0
total	28	28	100.0

package Mojo::Log::Colored;
use Mojo::Base 'Mojo::Log';
use Term::ANSIColor 'colored';

use if $^O eq "MSWin32", "Win32::Console::ANSI";

our $VERSION = "0.04";

has 'colors' => sub {
    return {
        debug => "bold bright_white",
        info  => "bold bright_blue",
        warn  => "bold green",
        error => "bold yellow",
        fatal => "bold yellow on_red",
    };
};

has _format => sub {
    shift->format( \&_default_format );
};

sub format {
    return $_[0]->_format if @_ == 1;

    my ( $self, $format ) = @_;

    return $self->_format(
        sub {
            # Prevent having the end escape sequence at the start of the line
            local $Term::ANSIColor::EACHLINE = "\n";
            # only add colors if we have a color for this level
            exists $self->colors->{ $_[1] }
                ? colored( $format->(@_), $self->colors->{ $_[1] } )
                : $format->(@_);
        }
    )->_format;
}

# use the default logger format based on the Mojo version we're running under
sub _default_format;
if ($Mojolicious::VERSION && $Mojolicious::VERSION >= 9) {
    *_default_format = sub {
        '[' . localtime(shift) . '] [' . shift() . '] ' . join(' ', @_, "\n");
    };
} else {
    *_default_format = sub {
        '[' . localtime(shift) . '] [' . shift() . '] ' . join("\n", @_, '');
    };
}

1;
__END__