File Coverage

blib/lib/Mojar/Message/BulkSms.pm

Criterion	Covered	Total	%
statement	37	55	67.2
branch	8	22	36.3
condition	6	9	66.6
subroutine	8	11	72.7
pod	1	5	20.0
total	60	102	58.8

package Mojar::Message::BulkSms;
use Mojo::Base -base;

our $VERSION = 1.002;

use Mojar::Log;
use Mojo::Parameters;
use Mojo::UserAgent;

# Attributes

has protocol => 'http';
has address => 'www.bulksms.co.uk';
has port => '5567';
has path => 'eapi/submission/send_sms/2/2.0';
has gateway => sub {
  my $self = shift;
  $self->path;
  $self->{path} =~ s{^/}{};
  sprintf '%s://%s:%s/%s',
      $self->protocol, $self->address, $self->port, $self->path
};

has 'username';
has 'password';
has 'recipient';
has 'sender';
has international_prefix => '44';
sub msisdn { $_[0]->{recipient} }  # read-only alias

has 'message';
has ua => sub { Mojo::UserAgent->new(request_timeout => 15) };
has log => sub { Mojar::Log->new };

# Public methods

sub send {
  my $self = shift;
  my $cb = @_ && ref $_[-1] eq 'CODE' ? pop : undef;
  return $self->handle_error({
    message => sprintf('Unhandled args (%s)', join ',', @_),
    advice => -1
  } => $cb) unless @_ % 2 == 0;
  %$self = (%$self, @_) if @_;

  my @missing = grep +(not exists $self->{$_}),
      qw(username password recipient message);
  return $self->handle_error({
    message => sprintf('Missing parameters (%s)', join ',', @missing),
    advice => -2
  } => $cb) if @missing;

  # Clean up recipient
  my $original_recipient = $self->{recipient};
  my $prefix = $self->international_prefix;
  $self->{recipient} =~ s/\D//g;  # collapse non-digits
  $self->{recipient} =~ s/^00//;  # international
  $self->{recipient} =~ s/^0/$prefix/;  # national
  $self->log->debug(sprintf 'Preparing to send SMS to %s (%s)',
      $original_recipient, $self->{recipient});

  # Clean up message
  $self->trim_message;

  my $p = Mojo::Parameters->new;
  $p->append($_ => $self->$_) for qw(username password msisdn sender message);

  return $self->submit(sprintf('%s?%s', $self->gateway, $p->to_string) => $cb);
}

sub submit {
  my ($self, $url, $cb) = @_;
  # Call the gateway
  local $ENV{MOJO_USERAGENT_DEBUG} = !! $ENV{MOJAR_SMS_DEBUG};
  if ($cb) {
    $self->ua->get($url => sub { _check_status($self, $cb, @_) });
    return $self;
  }
  else {
    my $tx = $self->ua->get($url);
    return _check_status($self, $cb, undef, $tx);
  }
}

sub _check_status {
  my ($self, $cb, undef, $tx) = (@_);

  # Check http errors
  my ($error, $advice);
  return $self->handle_error($error => $cb) if $error = $tx->error;

  # Check service errors
  eval {
    @$error{'advice', 'message'} = split /\|/, $tx->res->body;
    length($advice = $error->{advice} //= '-3') == 1 and $advice == 0;
  }
  or do {
    @$error{'advice', 'message'} = (-4, $@) if $@;
    return $self->handle_error($error => $cb);
  };

  $self->log->debug('Sent to '. $self->recipient);
  return $cb ? $cb->($self) : $self;
}

sub handle_error {
  my ($self, $error, $cb) = @_;
  $self->log->error(sprintf 'Failed with %u:%s',
      $error->{advice} //= 418, $error->{message} //= 'coded failure');
  return $cb ? $cb->($self, $error) : undef;
}

sub trim_message {
  my $self = $_[0];
  $self->{message} =~ s/^\s+//;
  $self->{message} =~ s/\s+$//;
  $self->{message} =~ s/\s\s+/ /g;
  return $self;
}

1;
__END__