File Coverage

blib/lib/Mojar/Cron/Holiday.pm

Criterion	Covered	Total	%
statement	26	28	92.8
branch	12	14	85.7
condition	6	9	66.6
subroutine	5	6	83.3
pod	2	3	66.6
total	51	60	85.0

package Mojar::Cron::Holiday;
use Mojo::Base -base;

use Carp 'croak';
use Mojar::Cron::Datetime;

# Attributes

has holidays => sub { {} };
has 'linked';
has 'error';

# Methods

sub holiday {
  my ($self, $date) = (shift, shift);
  $date //= substr(Mojar::Cron::Datetime->now->to_string, 0, 10);
  my $holidays = $self->holidays;
  my $linked = $self->linked;

  if (ref $date eq 'ARRAY') {
    # Recurse over a setter bundle
    return [map $self->holiday($_ => $_[0]), @$date] if @_;

    # Recurse over a getter bundle
    return [map $self->holiday($_), @$date];
  }

  # Scalar
  croak 'Bad format' unless $date =~ /^\d\d\d\d-\d\d-\d\d$/;

  # Setter
  $holidays->{$date} = !! $_[0], return $self if @_;

  # Getter
  return $holidays->{$date} if exists $holidays->{$date};

  # Defer if possible
  return $linked->holiday($date) if $linked;

  # Negative
  return undef;
}

sub next_holiday {
  my ($self, $date) = @_;
  $date //= substr(Mojar::Cron::Datetime->now->to_string, 0, 10);
  my $holidays = $self->holidays;

  my @dates = sort grep $holidays->{$_}, keys %$holidays;
  shift @dates while @dates and $dates[0] lt $date;
  @dates ? $dates[0] : undef;
}

sub load { croak q{Method 'load' not implemented by subclass} }

1;
__END__