File Coverage

blib/lib/Module/Reload.pm

Criterion	Covered	Total	%
statement	27	33	81.8
branch	11	18	61.1
condition			n/a
subroutine	4	4	100.0
pod	0	1	0.0
total	42	56	75.0

package Module::Reload;
$Module::Reload::VERSION = '1.10';
use 5.006;
use strict;
use warnings;

our $Debug = 0;
our %Stat;

sub check {
    my $c=0;

    foreach my $entry (map { [ $_, $INC{$_} ] } keys %INC) {
        my($key,$file) = @$entry;

        # If the require'ing of a file failed, but was caught by eval,
        # then we end up with a value of undef in %INC. Skip those.
        next unless defined($file);

        next if $file eq $INC{"Module/Reload.pm"};  #too confusing
        local $^W = 0;
        my $mtime = (stat $file)[9];
        $Stat{$file} = $^T unless defined $Stat{$file};

        if ($Debug >= 3) {
            warn "Module::Reload: stat '$file' got $mtime >? $Stat{$file}\n";
        }

        if ($mtime > $Stat{$file}) {
            delete $INC{$key};
            eval {
                local $SIG{__WARN__} = \&warn;
                require $key;
            };
            if ($@) {
                warn "Module::Reload: error during reload of '$key': $@\n";
            }
            elsif ($Debug) {
                if ($Debug == 1) {
                    warn "Module::Reload: process $$ reloaded '$key'\n";
                }
                if ($Debug >= 2) {
                    warn("Module::Reload: process $$ reloaded '$key' (\@INC=".
                         join(', ',@INC).")\n");
                }
            }
            ++$c;
        }
        $Stat{$file} = $mtime;
    }
    $c;
}

1;

__END__