File Coverage

blib/lib/Module/Pluggable/Dependency.pm

Criterion	Covered	Total	%
statement	38	41	92.6
branch	2	2	100.0
condition	4	12	33.3
subroutine	9	9	100.0
pod			n/a
total	53	64	82.8

package Module::Pluggable::Dependency;

use warnings;
use strict;
use Module::Pluggable ();
use Algorithm::Dependency::Ordered;
use Algorithm::Dependency::Source::HoA;

our $VERSION = '0.0.4';

sub import {
    my $package = shift;

    # let Module::Pluggable install it's normal subroutine
    my %args = @_;
    $args{package} ||= scalar caller;
    $args{require} = 1 if !$args{require} && !$args{instantiate};
    Module::Pluggable->import(%args);

    # wrap Module::Pluggable's sub to sort by dependencies
    my $sub_name = $args{sub_name} || 'plugins';
    my $installed_sub_name = "$args{package}::$sub_name";
    {
        no strict 'refs';
        no warnings 'redefine';
        my $original_sub = \&$installed_sub_name;
        *{$installed_sub_name} = sub {

            # build a dependency hash
            my %deps;
            my %objects;
            for my $plugin ( $original_sub->(@_) ) {
                my $plugin_name = ref($plugin) || $plugin;
                $deps{$plugin_name} = eval { [ $plugin->depends ] } || [];
                $objects{$plugin_name} = $plugin;
            }

            # calculate plugin order based on dependencies
            my $source = Algorithm::Dependency::Source::HoA->new( \%deps );
            my $deps
                = Algorithm::Dependency::Ordered->new( source => $source );
            return @objects{ @{ $deps->schedule_all } };
        };
    }
}

1;

__END__