File Coverage

blib/lib/Module/Loader.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	6	6	100.0
condition			n/a
subroutine	8	8	100.0
pod	3	3	100.0
total	57	57	100.0

package Module::Loader;
$Module::Loader::VERSION = '0.02';
use 5.006;
use Moo;
use Path::Iterator::Rule;
use File::Spec::Functions   qw/ catfile splitdir /;
use Carp                    qw/ croak /;

has 'max_depth' => (is => 'rw', clearer => 1);

sub find_modules
{
    my ($self, $base) = @_;
    my @baseparts     = split(/::/, $base);
    my %modules;

    foreach my $directory (@INC) {
        my $path = catfile($directory, @baseparts);
        next unless -d $path;

        my $rule = Path::Iterator::Rule->new->perl_module;
        $rule->max_depth($self->max_depth) if $self->max_depth;

        foreach my $file ($rule->all($path)) {
            (my $modpath = $file) =~ s!^\Q$directory\E.|\.pm$!!g;

            my $module = join('::', splitdir($modpath));

            # Using a hash means that even if a module is installed
            # in more than one place, it will only be reported once
            $modules{ $module }++;
        }
    }

    return keys(%modules);
}

sub search
{
    my $self      = shift;
    my $max_depth = $self->max_depth;

    $self->max_depth(1);

    my @modules   =  $self->find_modules(@_);

    if (defined $max_depth) {
        $self->max_depth($max_depth);
    }
    else {
        $self->clear_max_depth();
    }

    return @modules;
}

sub load
{
    my ($self, @modules) = @_;

    require Module::Runtime;
    foreach my $module (@modules) {
        Module::Runtime::require_module($module);
    }
}

1;

=encoding utf8

=head1 NAME

Module::Loader - finding and loading modules in a given namespace

=head1 SYNOPSIS

 use Module::Loader;

 my $loader  = Module::Loader->new;
 my @plugins = $loader->find_modules('MyApp::Plugin');

 foreach my $plugin (@plugins) {
    $loader->load($plugin);
 }

=head1 DESCRIPTION

This module provides methods for finding modules in a given namespace,
and then loading them. It is intended for use in situations where
you're looking for plugins, and then loading one or more of them.

This module was inspired by L, which I have used in
a number of projects. But some people were wary of requiring L
just to get a module loader, which prompted me to create C.

Note: this module was initially called C, but I realised
that C was a more appropriate name.

=head2 max_depth

C has an optional C attribute.
If you set this to 1, then C will only report modules
that are immediately within the namespace specified.

Let's say you have all of the CPAN plugins for the template toolkit
installed locally. If you don't specify C, then C
would return L
as well as L. If you set C to 1,
then you'd get the latter but not the former.

Why might you want to do that?

You might have a convention where plugins are the modules immediately
within the specified namespace, but that each plugin can have additional
modules within its own namespace.

So typically you'll either not set C, or you'll set it to 1.

=head1 METHODS

=head2 find_modules

Takes a namespace, and returns all installed modules in that namespace,
that were found in C<@INC>. For example:

 @plugins = $loader->find_modules('Template::Plugin');

By default this will find all modules in the given namespace,
unless you've specified a maximum search depth, as described above.

=head2 search

This is the same as C above, but it hard-codes the search depth
to 1. This method is provided for compatibility with M:

 @plugins = $loader->search('Template::Plugin');

It preserves your current setting of the C attribute,
in the unlikely event that you want to interleave calls to C
and C.

=head2 load

Takes a module name and tries to load the module.
If loading fails, then we C.

=head1 SEE ALSO

L was the inspiration for this module, but has
a slightly different interface. In particular, it has C
hard-coded to 1.

L is effectively a role which gives a class the ability
to find plugins within its namespace.

L is similar to L,
but lets you control the order in which modules are loaded.

L will load all modules in a given namespace, eg with C

L will load all modules found in a given I
(as opposed to a namespace).

L provides functions for loading modules,
but not for finding them.

L provides a number of functions for finding and loading
modules. It provides different functions depending on whether you want
to limit the search depth to 1 or not: C vs C.

L will load all modules in a given namespace,
and return a list of the modules found / loaded.
It lets you provide regexps for filtering out certain namespaces.

L provides two functions, C
and C which will load all locally installed modules
whose name matches a pattern (specified as a regular expression
or glob-style pattern).

=head1 REPOSITORY

L

=head1 AUTHOR

Neil Bowers [e-mail]

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2014 by Neil Bowers .

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut