File Coverage

blib/lib/Module/Build/Prereq.pm

Criterion	Covered	Total	%
statement	40	42	95.2
branch	11	14	78.5
condition	3	8	37.5
subroutine	7	7	100.0
pod	1	1	100.0
total	62	72	86.1

package Module::Build::Prereq;

use 5.010000;
use strict;
use warnings;
use Module::CoreList;
use File::Find;

require Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(assert_modules);

our $VERSION = '0.04';

sub assert_modules {
    my %args = @_;

    my %modules = ();

    my $skips = $args{ignore_modules};
    my $finds = $args{module_paths} || ['lib'];
    my $ext   = $args{pm_extension} || qr(\.[Pp][Mm]$);

    find( sub { my $file = $_;
                return unless $file =~ $ext;

                open my $fh, "<", $file or do { warn "Unable to open $file: $!\n"; return; };
                while( my $module = <$fh> ) {
                    next unless $module =~ s/^use (\S+).*;.*/$1/;
                    chomp $module;
                    next if $module =~ /^\d/; # version pragma
                    next if exists $args{prereq_pm}->{$module};
                    next if defined $skips and $module =~ $skips;

                    $modules{$module} = $File::Find::name;
                }
                close $fh;
            }, @$finds );

    my $mod = join('|', sort keys %modules);
    my @core = Module::CoreList->find_modules(qr/^(?:$mod)$/);
    delete @modules{@core};

    if (scalar keys %modules) {
        my @missing = map { "  $_ (used by $modules{$_})" } sort keys %modules;
        die "Missing modules:\n" . join("\n", @missing) . "\n";
    }

    return 1;
}

1;
__END__