File Coverage

blib/lib/Module/Build/PodParser.pm

Criterion	Covered	Total	%
statement	41	43	95.3
branch	18	24	75.0
condition	2	2	100.0
subroutine	7	7	100.0
pod	0	4	0.0
total	68	80	85.0

package Module::Build::PodParser;

use strict;
use warnings;
our $VERSION = '0.42_35';
$VERSION = eval $VERSION;

sub new {
  # Perl is so fun.
  my $package = shift;

  my $self;
  $self = bless {have_pod_parser => 0, @_}, $package;

  unless ($self->{fh}) {
    die "No 'file' or 'fh' parameter given" unless $self->{file};
    open($self->{fh}, '<', $self->{file}) or die "Couldn't open $self->{file}: $!";
  }

  return $self;
}

sub parse_from_filehandle {
  my ($self, $fh) = @_;

  local $_;
  while (<$fh>) {
    next unless /^ =encoding \s+ (\S+)/ix;
    binmode $fh, ":encoding($1)";
    last;
  }
  seek $fh, 0, 0;

  while (<$fh>) {
    next unless /^=(?!cut)/ .. /^=cut/;  # in POD
    # Accept Name - abstract or C - abstract
    last if ($self->{abstract}) = /^ (?: [a-z_0-9:]+ | [BCIF] < [a-z_0-9:]+ > ) \s+ - \s+ (.*\S) /ix;
  }

  my @author;
  while (<$fh>) {
    next unless /^=head1\s+AUTHORS?/i ... /^=/;
    next if /^=/;
    push @author, $_ if /\@/;
  }
  return unless @author;
  s/^\s+|\s+$//g foreach @author;

  $self->{author} = \@author;

  return;
}

sub get_abstract {
  my $self = shift;
  return $self->{abstract} if defined $self->{abstract};

  $self->parse_from_filehandle($self->{fh});

  return $self->{abstract};
}

sub get_author {
  my $self = shift;
  return $self->{author} if defined $self->{author};

  $self->parse_from_filehandle($self->{fh});

  return $self->{author} || [];
}