File Coverage

blib/lib/Modern/Perl.pm

Criterion	Covered	Total	%
statement	44	47	93.6
branch	12	16	75.0
condition	1	4	25.0
subroutine	11	11	100.0
pod	0	2	0.0
total	68	80	85.0

package Modern::Perl;
# ABSTRACT: enable all of the features of Modern Perl with one import
$Modern::Perl::VERSION = '1.20220515';
use 5.010_000;

use strict;
use warnings;

use mro     ();
use feature ();

# enable methods on filehandles; unnecessary when 5.14 autoloads them
use IO::File   ();
use IO::Handle ();

my $wanted_date;

sub VERSION {
    my ($self, $version) = @_;

    return $Modern::Perl::VERSION || 2022 unless defined $version;
    return $Modern::Perl::VERSION || 2022 if             $version < 2009;

    $wanted_date = $version if (caller(1))[3] =~ /::BEGIN/;
    return 2022;
}

sub import {
    my ($class, $date) = @_;
    $date = $wanted_date unless defined $date;

    my $feature_tag    = validate_date( $date );
    undef $wanted_date;

    warnings->import;
    strict->import;
    feature->import( $feature_tag );

    if ($feature_tag ge ':5.34') {
        feature->import( 'signatures' );
        warnings->unimport( 'experimental::signatures' );
    }

    mro::set_mro( scalar caller(), 'c3' );
}

sub unimport {
    warnings->unimport;
    strict->unimport;
    feature->unimport;
}

sub validate_date {
    my %dates = (
        2009 => ':5.10',
        2010 => ':5.10',
        2011 => ':5.12',
        2012 => ':5.14',
        2013 => ':5.16',
        2014 => ':5.18',
        2015 => ':5.20',
        2016 => ':5.24',
        2017 => ':5.24',
        2018 => ':5.26',
        2019 => ':5.28',
        2020 => ':5.30',
        2021 => ':5.32',
        2022 => ':5.34',
    );

    my $date = shift;

    # always enable unicode_strings when available
    unless ($date) {
        return ':5.12' if $] > 5.011003;
        return ':5.10';
    }

    my $year = substr $date, 0, 4;
    return $dates{$year} if exists $dates{$year};

    die "Unknown date '$date' requested\n";
}


1;

__END__