File Coverage

blib/lib/Mock/Person/JP.pm

Criterion	Covered	Total	%
statement	46	46	100.0
branch	8	8	100.0
condition	3	3	100.0
subroutine	10	10	100.0
pod	2	2	100.0
total	69	69	100.0

package Mock::Person::JP;

use 5.008_001;
use strict;
use warnings;
use Carp ();
use File::ShareDir   ();
use File::RandomLine ();
use Mock::Person::JP::Person ();

our $VERSION = "0.07";

sub new
{
    my ($class) = @_;

    my $self = bless {}, $class;

    $self->{sei}         = File::RandomLine->new( File::ShareDir::dist_file('Mock-Person-JP', 'sei.tsv') );
    $self->{mei}{male}   = File::RandomLine->new( File::ShareDir::dist_file('Mock-Person-JP', 'mei_male.tsv') );
    $self->{mei}{female} = File::RandomLine->new( File::ShareDir::dist_file('Mock-Person-JP', 'mei_female.tsv') );

    return $self;
}

sub create_person
{
    my $self = shift;

    my %arg = (ref $_[0] eq 'HASH') ? %{$_[0]} : @_;

    Carp::croak('sex option required') unless exists $arg{sex};

    for my $key (keys %arg)
    {
        if ($key eq 'sex')
        {
            Carp::croak("sex option must be 'male' or 'female'") if $arg{$key} ne 'male' && $arg{$key} ne 'female';
        }
        else { Carp::croak "Unknown option: '$key'";  }
    }

    $arg{name} = $self->_rand_name($arg{sex});

    return Mock::Person::JP::Person->new(\%arg);
}

sub _rand_name
{
    my ($self, $sex) = @_;

    my $sei = $self->{sei}->next;
    my $mei = $self->{mei}{$sex}->next;

    # Faster than Encode::decode_utf8 and no need to validate the string
    utf8::decode($sei);
    utf8::decode($mei);

    my %name;
    ($name{sei_yomi}, $name{sei}) = split(/\t/, $sei);
    ($name{mei_yomi}, $name{mei}) = split(/\t/, $mei);

    return \%name;
}

1;

__END__