File Coverage

blib/lib/Mock/Data/GeneratorSub.pm

Criterion	Covered	Total	%
statement	24	35	68.5
branch	10	20	50.0
condition	1	6	16.6
subroutine	6	7	85.7
pod	3	3	100.0
total	44	71	61.9

package Mock::Data::GeneratorSub;
use strict;
use warnings;
require Mock::Data::Generator;
our @ISA= qw( Mock::Data::Generator );

# ABSTRACT: Wrap a coderef to become a blessed Generator object
our $VERSION = '0.03'; # VERSION


sub new {
	my ($class, $coderef, @params)= @_;
	if (ref $coderef eq 'HASH') {
		@params= @{ $coderef->{params} || [] };
		$coderef= $coderef->{coderef};
	}
	if (ref $class) {
		$coderef ||= $class->{coderef};
		@params= $class->_merge_params(@params);
		$class= ref $class;
	}
	Scalar::Util::reftype($coderef) eq 'CODE' or Carp::croak("Not a coderef");
	bless {
		coderef => $coderef,
		params => \@params,
	}, $class;
}

sub _merge_params {
	my $self= shift;
	my $p= $self->{params};
	my $named_p= ref $p->[0] eq 'HASH'? $p->[0] : undef;
	# Merge any options-by-name newly supplied with options-by-name from @params
	unshift @_, (ref $_[0] eq 'HASH')? { %$named_p, %{shift @_} } : $named_p
		if $named_p;
	# Append positional params if none provided
	push @_, @{$p}[1..$#$p]
		unless @_ > 1;
	return @_;
}


sub generate {
	my ($self, $mock)= (shift, shift);
	$self->{coderef}->($mock, @_? $self->_merge_params(@_) : @{$self->{params}});
}


sub compile {
	my $self= shift;
	my $params= $self->{params};
	return $self->{coderef} unless @_ || @$params;
	my @new_params= $self->_merge_params(@_);
	my $coderef= $self->{coderef};
	return sub { $coderef->(shift, @new_params) };
}

1;

__END__