File Coverage

blib/lib/Minion/Backend/Sereal.pm

Criterion	Covered	Total	%
statement	233	236	98.7
branch	65	74	87.8
condition	114	135	84.4
subroutine	48	48	100.0
pod	21	21	100.0
total	481	514	93.5

package Minion::Backend::Sereal;
use Minion::Backend -base;

our $VERSION = 7.012;

use Sys::Hostname 'hostname';
use Time::HiRes qw(time usleep);

# Attributes

has 'file';

# Constructor

sub new { shift->SUPER::new(file => shift) }

# Methods

sub broadcast {
  my ($self, $command, $args, $ids) = (shift, shift, shift // [], shift // []);

  my $guard = $self->_guard->_write;
  my $inboxes = $guard->_inboxes;
  my $workers = $guard->_workers;
  @$ids = @$ids ? map exists($workers->{$_}), @$ids
      : keys %$workers unless @$ids;

  push @{$inboxes->{$_} //= []}, [$command, @$args] for @$ids;

  return !!@$ids;
}

sub dequeue {
  my ($self, $id, $wait, $options) = @_;
  return ($self->_try($id, $options) or do {
    usleep $wait * 1_000_000;
    $self->_try($id, $options);
  });
}

sub enqueue {
  my ($self, $task, $args, $options) = (shift, shift, shift // [], shift // {});

  my $guard = $self->_guard->_write;

  my $job = {
    args     => $args,
    attempts => $options->{attempts} // 1,
    created  => time,
    delayed  => time + ($options->{delay} // 0),
    id       => $guard->_job_id,
    notes    => $options->{notes} // {},
    parents  => $options->{parents} // [],
    priority => $options->{priority} // 0,
    queue    => $options->{queue} // 'default',
    retries  => 0,
    state    => 'inactive',
    task     => $task
  };
  $guard->_jobs->{$job->{id}} = $job;

  return $job->{id};
}

sub fail_job { shift->_update(1, @_) }

sub finish_job { shift->_update(0, @_) }

sub job_info {
  my ($self, $id) = @_;
  my $guard = $self->_guard;
  return undef unless my $job = $guard->_jobs->{$id};
  $job->{children} = $guard->_children($id);
  return $job;
}

sub list_jobs {
  my ($self, $offset, $limit, $options) = @_;

  my $guard = $self->_guard;
  my @jobs = sort { $b->{created} <=> $a->{created} }
  grep +( (not defined $options->{queue} or $_->{queue} eq $options->{queue})
      and (not defined $options->{state} or $_->{state} eq $options->{state})
      and (not defined $options->{task}  or $_->{task} eq $options->{task})
  ), values %{$guard->_jobs};

  return [map +($_->{children} = $guard->_children($_->{id}) and $_), grep defined, @jobs[$offset .. ($offset + $limit - 1)]];
}

sub list_workers {
  my ($self, $offset, $limit) = @_;
  my $guard = $self->_guard;
  my @workers = map { $self->_worker_info($guard, $_->{id}) }
    sort { $b->{started} <=> $a->{started} } values %{$guard->_workers};
  return [grep {defined} @workers[$offset .. ($offset + $limit - 1)]];
}

sub lock {
  my ($self, $name, $duration, $options) = (shift, shift, shift, shift // {});
  my $limit = $options->{limit} || 1;

  my $guard = $self->_guard->_write;
  my $locks = $guard->_locks->{$name} //= [];

  # Delete expired locks
  my $now = time;
  @$locks = grep +($now < ($_ // 0)), @$locks;

  # Check capacity
  return undef unless @$locks < $limit;
  return 1 unless $duration > 0;

  # Add lock, maintaining order
  my $this_expires = $now + $duration;

  push(@$locks, $this_expires) and return 1
    if ($locks->[$#$locks] // 0) < $this_expires;

  @$locks = sort { ($a // 0) <=> ($b // 0) } (@$locks, $this_expires);
  return 1;
}

sub note {
  my ($self, $id, $key, $value) = @_;
  my $guard = $self->_guard;
  return undef unless my $job = $guard->_write->_jobs->{$id};
  $job->{notes}{$key} = $value;
  return 1;
}

sub receive {
  my ($self, $id) = @_;
  my $guard = $self->_guard->_write;
  my $inboxes = $guard->_inboxes;
  my $inbox = $inboxes->{$id} // [];
  $inboxes->{$id} = [];
  return $inbox;
}

sub register_worker {
  my ($self, $id, $options) = (shift, shift, shift // {});
  my $guard = $self->_guard->_write;
  my $worker = $id ? $guard->_workers->{$id} : undef;
  unless ($worker) {
    $worker = {host => hostname, id => $guard->_id, pid => $$, started => time};
    $guard->_workers->{$worker->{id}} = $worker;
  }
  @$worker{qw(notified status)} = (time, $options->{status} // {});
  return $worker->{id};
}

sub remove_job {
  my ($self, $id) = @_;
  my $guard = $self->_guard;
  delete $guard->_write->_jobs->{$id}
    if my $removed = !!$guard->_job($id, qw(failed finished inactive));
  return $removed;
}

sub repair {
  my $self = shift;
  my $minion = $self->minion;

  # Workers without heartbeat
  my $guard   = $self->_guard->_write;
  my $workers = $guard->_workers;
  my $jobs    = $guard->_jobs;
  my $after   = time - $minion->missing_after;
  $_->{notified} < $after and delete $workers->{$_->{id}} for values %$workers;

  # Old jobs without unfinished dependents
  $after = time - $minion->remove_after;
  for my $job (values %$jobs) {
    next unless $job->{state} eq 'finished' and $job->{finished} <= $after;
    delete $jobs->{$job->{id}} unless grep +($jobs->{$_}{state} ne 'finished'),
        @{$guard->_children($job->{id})};
  }

  # Jobs with missing worker (can be retried)
  my @abandoned = map [@$_{qw(id retries)}],
      grep +($_->{state} eq 'active' and not exists $workers->{$_->{worker}}),
      values %$jobs;
  undef $guard;
  $self->fail_job(@$_, 'Worker went away') for @abandoned;

  return;
}

sub reset { $_[0]->_guard->_save({} => $_[0]{file}) }

sub retry_job {
  my ($self, $id, $retries, $options) = (shift, shift, shift, shift // {});

  my $guard = $self->_guard;
  return undef
    unless my $job = $guard->_job($id, qw(active failed finished inactive));
  return undef unless $job->{retries} == $retries;
  $guard->_write;
  ++$job->{retries};
  $job->{delayed} = time + $options->{delay} if $options->{delay};
  exists $options->{$_} and $job->{$_} = $options->{$_} for qw(priority queue);
  @$job{qw(retried state)} = (time, 'inactive');
  delete @$job{qw(finished started worker)};

  return 1;
}

sub stats {
  my $self = shift;

  my ($active, $delayed) = (0, 0);
  my (%seen, %states);
  my $guard = $self->_guard;
  for my $job (values %{$guard->_jobs}) {
    ++$states{$job->{state}};
    ++$active if $job->{state} eq 'active' and not $seen{$job->{worker}}++;
    ++$delayed if $job->{state} eq 'inactive'
        and (time < $job->{delayed} or @{$job->{parents}});
  }

  return {
    active_workers   => $active,
    inactive_workers => keys(%{$guard->_workers}) - $active,
    active_jobs      => $states{active}   // 0,
    delayed_jobs     => $delayed,
    enqueued_jobs    => $guard->_job_count,
    failed_jobs      => $states{failed}   // 0,
    finished_jobs    => $states{finished} // 0,
    inactive_jobs    => $states{inactive} // 0
  };
}

sub unlock {
  my ($self, $name) = @_;

  my $guard = $self->_guard->_write;
  my $locks = $guard->_locks->{$name} //= [];
  my $length = @$locks;
  my $now = time;

  my $i = 0;
  ++$i while $i < $length and ($locks->[$i] // 0) <= $now;
  return undef if $i >= $length;

  $locks->[$i] = undef;
  return 1;
}

sub unregister_worker {
  my ($self, $id) = @_;
  my $guard = $self->_guard->_write;
  delete $guard->_inboxes->{$id};
  delete $guard->_workers->{$id};
}

sub worker_info { $_[0]->_worker_info($_[0]->_guard, $_[1]) }

sub _guard { Minion::Backend::Sereal::_Guard->new(backend => shift) }

sub _try {
  my ($self, $id, $options) = @_;
  my $tasks = $self->minion->tasks;
  my %queues = map +($_ => 1), @{$options->{queues} // ['default']};

  my $now = time;
  my $guard = $self->_guard;
  my $jobs = $guard->_jobs;
  my @ready = sort { $b->{priority} <=> $a->{priority}
        || $a->{created} <=> $b->{created} }
    grep +($_->{state} eq 'inactive' and $queues{$_->{queue}}
        and $tasks->{$_->{task}} and $_->{delayed} <= $now),
    values %$jobs;

  my $job;
  CANDIDATE: for my $candidate (@ready) {
    $job = $candidate and last CANDIDATE
      unless my @parents = @{$candidate->{parents} // []};
    for my $parent (@parents) {
      next CANDIDATE if exists $jobs->{$parent}
          and grep +($jobs->{$parent}{state} eq $_), qw(active failed inactive)
    }
    $job = $candidate;
  }

  return undef unless $job;
  $guard->_write;
  @$job{qw(started state worker)} = (time, 'active', $id);
  return $job;
}

sub _update {
  my ($self, $fail, $id, $retries, $result) = @_;

  my $guard = $self->_guard;
  return undef unless my $job = $guard->_job($id, 'active');
  return undef unless $job->{retries} == $retries;

  $guard->_write;
  @$job{qw(finished result)} = (time, $result);
  $job->{state} = $fail ? 'failed' : 'finished';
  undef $guard;

  return 1 unless $fail and $job->{attempts} > $retries + 1;
  my $delay = $self->minion->backoff->($retries);
  return $self->retry_job($id, $retries, {delay => $delay});
}

sub _worker_info {
  my ($self, $guard, $id) = @_;

  return undef unless $id && (my $worker = $guard->_workers->{$id});
  my @jobs = map $_->{id},
      grep +($_->{state} eq 'active' and $_->{worker} eq $id),
      values %{$guard->_jobs};

  return {%$worker, jobs => \@jobs};
}

package
    Minion::Backend::Sereal::_Guard;
use Mojo::Base -base;

use Fcntl ':flock';
use Digest::MD5 'md5_hex';
use Sereal::Decoder 'sereal_decode_with_object';
use Sereal::Encoder 'sereal_encode_with_object';

sub DESTROY {
  $_[0]->_save($_[0]->_data => $_[0]{backend}{file}) if $_[0]{write};
  flock $_[0]{lock}, LOCK_UN;
}

sub new {
  my $self = shift->SUPER::new(@_);
  my $path = $self->{backend}{file};
  $self->_save({} => $path) unless -f $path;
  open $self->{lock}, '>', "$path.lock";
  flock $self->{lock}, LOCK_EX;
  return $self;
}

sub _children {
  my ($self, $id) = @_;
  my $children = [];
  for my $job (values %{$self->_jobs}) {
    push @$children, $job->{id} if grep +($_ eq $id), @{$job->{parents} // []};
  }
  return $children;
}

sub _data { $_[0]{data} //= $_[0]->_load($_[0]{backend}{file}) }

sub _id {
  my $id;
  do { $id = md5_hex(time . rand 999) } while $_[0]->_workers->{$id};
  return $id;
}

sub _inboxes { $_[0]->_data->{inboxes} //= {} }

sub _job {
  my ($self, $id) = (shift, shift);
  return undef unless my $job = $self->_jobs->{$id};
  return grep(($job->{state} eq $_), @_) ? $job : undef;
}

sub _job_count { $_[0]->_data->{job_count} //= 0 }

sub _job_id {
  my $id;
  do { $id = md5_hex(time . rand 999) } while $_[0]->_jobs->{$id};
  ++$_[0]->_data->{job_count};
  return $id;
}

sub _jobs { $_[0]->_data->{jobs} //= {} }

sub _load {
  my ($self, $path) = @_;
  my $decoder = $self->{backend}{_guard_decoder} //= Sereal::Decoder->new;

  # Borrowed from Mojo::File v7.33
  CORE::open my $file, '<', $path or die qq{Failed to open file ($path): $!};
  my ($payload, $ret) = ('', undef);
  while ($ret = sysread $file, my $buffer, 131072, 0) { $payload .= $buffer }
  die qq{Failed to read file ($path): $!} unless defined $ret;

  return sereal_decode_with_object $decoder, $payload;
}

sub _locks { shift->_data->{locks} //= {} }

sub _save {
  my ($self, $content, $path) = @_;
  my $encoder = $self->{backend}{_guard_encoder} //= Sereal::Encoder->new;
  my $payload = sereal_encode_with_object $encoder, $content;

  # Borrowed from Mojo::File v7.33
  CORE::open my $file, '>', $path or die qq{Failed to open file ($path): $!};
  (syswrite($file, $payload) // -1) == length $payload
    or die qq{Failed to write file ($path): $!};
  return;
}

sub _workers { $_[0]->_data->{workers} //= {} }

sub _write { ++$_[0]{write} && return $_[0] }

1;
__END__