File Coverage

blib/lib/MikroTik/Client/Response.pm

Criterion	Covered	Total	%
statement	18	18	100.0
branch	5	6	83.3
condition	2	3	66.6
subroutine	3	3	100.0
pod	1	1	100.0
total	29	31	93.5

package MikroTik::Client::Response;
use MikroTik::Client::Mo;

use MikroTik::Client::Sentence;

has data     => [];
has sentence => sub { MikroTik::Client::Sentence->new() };

sub parse {
    my ($self, $buf) = @_;

    my $data = [];

    my $sentence = $self->sentence;
    while ($$buf) {
        my $words = $sentence->fetch($buf);
        last if $sentence->is_incomplete;

        my $item = {'.tag' => '', '.type' => (shift @$words)};
        push @$data, $item;

        next unless @$words;

        while (my $w = shift @$words) {
            $item->{$1 || $2} = $3 if ($w =~ /^(?:=([^=]+)|(\.tag))=(.*)/s);
        }
    }

    return $self->{data} = $data;
}

1;

=encoding utf8

=head1 NAME

MikroTik::Client::Response - Parse responses from a buffer

=head1 SYNOPSIS

  use MikroTik::Client::Response;

  my $response = MikroTik::Client::Response->new();

  my $list = $response->parse(\$buf);
  for my $re (@$list) {
      my ($type, $tag) = delete @{$re}{'.type'. '.tag'};
      say "$_ => $re->{$_}" for keys %$re;
  }

=head1 DESCRIPTION

Parser for API protocol responses.

=head1 ATTRIBUTES

L implements the following attributes.

=head2 data

  my $items = $response->data;

Sentences fetched in last operation;

=head2 sentence

  my $sentence = $response->sentence;
  $response->sentence(MikroTik::Client::Sentence->new());

L object used to decode sentences from network buffer.

=head1 METHODS

=head2 parse

  my $list = $response->parse(\$buf);

Parses data from a buffer and returns list of hashrefs with attributes for each
sentence. There are some special attributes:

=over 2

=item '.tag'

  '.tag' => 1

Reply tag.

=item '.type'

  '.type' => '!re'

Reply type.

=back

=head1 SEE ALSO

L

=cut