File Coverage

blib/lib/Mew.pm

Criterion	Covered	Total	%
statement	37	39	94.8
branch	15	16	93.7
condition	7	9	77.7
subroutine	5	5	100.0
pod			n/a
total	64	69	92.7

package Mew;

use strictures 2;

our $VERSION = '1.002001'; # VERSION

use Import::Into;
use Moo;

sub import {
    my $class = shift;
    strictures->import::into(1);
    Moo->import::into(1);
    MooX->import::into(1, $_) for @_;
    MooX::ChainedAttributes->import::into(1);
    Types::Standard->import::into(1, qw/:all/);
    Types::Common::Numeric->import::into(1, qw/:all/);

    my $target = caller;
    my $moo_has = $target->can('has');
    Moo::_install_tracked $target => has => sub {
        my $name_proto = shift;
        my @name_proto = ref $name_proto eq 'ARRAY'
            ? @$name_proto : $name_proto;

        my $req = 1;
        my $mew_type;
        $mew_type = shift if @_ % 2 != 0;
        if ($mew_type and $mew_type->is_parameterized and $mew_type->parent == Types::Standard::Optional()) {
            $req = 0;
            $mew_type = $mew_type->type_parameter;
        }
        elsif ($mew_type and $mew_type == Types::Standard::Optional()) {
            $req = 0;
            $mew_type = Types::Standard::Any();
        }
        for my $attr ( @name_proto ) {
            my %spec = @_;
            if ( $mew_type ) {
                my %mew_spec;
                $mew_spec{required} = $req unless $attr =~ s/^-//;
                ( $mew_spec{init_arg} = $attr ) =~ s/^_//
                    unless exists $spec{init_arg};

                %spec = (
                    is  => $spec{chained} ? 'rw' : 'ro' ,
                    isa => $mew_type,
                    %mew_spec,
                    %spec,
                );
            }
            $moo_has->( $attr => %spec );
        }

        return;
    };

    namespace::clean->import::into(1);
}

q|
    To err is human -- and to blame it on a computer is even more so
|;

__END__