File Coverage

blib/lib/Method/Assert.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	18	24	75.0
condition			n/a
subroutine	9	9	100.0
pod			n/a
total	66	72	91.6

use strict;
use warnings;
package Method::Assert;
BEGIN {
  $Method::Assert::VERSION = '0.0.1';
}

# ABSTRACT: Ensure instance and class methods are called properly

use Scalar::Util qw(blessed);
use Carp qw(confess);

sub import {
    my $package = caller();

    confess("Importing into package 'main' makes no sense") if $package eq 'main';

    my $class_method = sub {
        confess("Method invoked as a function")                       if     @_ == 0;
        confess("Class method invoked as an instance method")         if     blessed( $_[0] );
        confess("Invocant is a reference, not a simple scalar value") if     ref($_[0]);
        confess("Invocant '$_[0]' is not a subclass of '$package'")   unless $_[0]->isa($package);
        return @_    if wantarray;         # list   context
        return shift if defined wantarray; # scalar context
        return;                            # void   context
    };

    my $instance_method = sub {
        confess("Method invoked as a function")                                           if     @_ == 0;
        confess("Method not invoked as an instance method")                               unless blessed( $_[0] );
        confess("Invocant of class '" . ref($_[0]) . "' is not a subclass of '$package'") unless $_[0]->isa($package);
        return @_    if wantarray;         # list   context
        return shift if defined wantarray; # scalar context
        return;                            # void   context
    };

    {
        no strict 'refs';
        *{ $package . '::class_method' } = $class_method;
        *{ $package . '::instance_method' } = $instance_method;
    }

    return 1;
}


1;

__END__