File Coverage

blib/lib/Metabase/Resource/cpan/distfile.pm

Criterion	Covered	Total	%
statement	40	41	97.5
branch	5	10	50.0
condition	1	5	20.0
subroutine	10	10	100.0
pod	1	1	100.0
total	57	67	85.0

use 5.006;
use strict;
use warnings;

package Metabase::Resource::cpan::distfile;

our $VERSION = '0.025';

use Carp               ();
use CPAN::DistnameInfo ();

use Metabase::Resource::cpan;
our @ISA = qw/Metabase::Resource::cpan/;

sub _metadata_types {
    return {
        cpan_id      => '//str',
        dist_file    => '//str',
        dist_name    => '//str',
        dist_version => '//str',
    };
}

sub _init {
    my ($self) = @_;

    # determine subtype
    my ($string) = $self =~ m{\Acpan:///distfile/(.+)\z};
    Carp::confess("could not determine distfile from '$self'\n")
      unless defined $string && length $string;

    my $data = $self->_validate_distfile($string);
    for my $k ( keys %$data ) {
        $self->_add( $k => $data->{$k} );
    }
    return $self;
}

# distfile validates during _init, really
sub validate { 1 }

# XXX should really validate AUTHOR/DISTNAME-DISTVERSION.SUFFIX
# -- dagolden, 2010-01-27
#
# my $suffix = qr{\.(?:tar\.(?:bz2|gz|Z)|t(?:gz|bz)|zip)};
#
# for now, we'll use CPAN::DistnameInfo;
#

# map DistnameInfo calls to our names
my %distfile_map = (
    cpanid  => 'cpan_id',
    dist    => 'dist_name',
    version => 'dist_version',
);

sub _validate_distfile {
    my ( $self, $string ) = @_;
    my $two = substr( $string, 0, 2 );
    my $one = substr( $two,    0, 1 );
    my $path = "authors/id/$one/$two/$string";
    my $d    = eval { CPAN::DistnameInfo->new($path) };
    my $bad  = defined $d ? 0 : 1;

    my $cache = { dist_file => $string };

    for my $k ( $bad ? () : ( keys %distfile_map ) ) {
        my $value = $d->$k;
        defined $value or $bad++ and last;
        $cache->{ $distfile_map{$k} } = $value;
    }

    if ($bad) {
        Carp::confess("'$string' can't be parsed as a CPAN distfile");
    }
    return $cache;
}

1;

# ABSTRACT: class for Metabase resources

__END__