File Coverage

blib/lib/Pod/Simple/Role/XHTML/WithPostProcess.pm

Criterion	Covered	Total	%
statement	13	13	100.0
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod	2	2	100.0
total	20	20	100.0

package Pod::Simple::Role::XHTML::WithPostProcess;
use Moo::Role;

our $VERSION = '0.003000';
$VERSION =~ tr/_//d;

use namespace::clean;

around new => sub {
  my $orig = shift;
  my $class = shift;
  my $self = $class->$orig(@_);
  open my $fh, '>', \($self->{__buffer} = '') or die;
  $self->{__real_output_fh} = $self->{output_fh};
  $self->{output_fh} = $fh;
  return $self;
};

around output_fh => sub {
  my $orig = shift;
  my $self = shift;
  if (@_) {
    $self->{__real_output_fh} = $_[0];
  }
  else {
    return $self->{__real_output_fh};
  }
};

around output_string => sub {
  my $orig = shift;
  my $self = shift;
  return $self->$orig(@_)
    if !@_;

  local $self->{output_fh} = $self->{__real_output_fh};
  my $output = $self->$orig(@_);
  $self->{__real_output_fh} = $self->{output_fh};
  return $output;
};

sub pre_process {
  my ($self, $content) = @_;
  return $content;
}

sub post_process {
  my ($self, $output) = @_;
  return $output;
}

after end_Document => sub {
  my ($self) = @_;
  my $full_content = $self->{__buffer};
  $self->{__buffer} = '';
  print { $self->{__real_output_fh} } $self->post_process($full_content);
};

before emit => sub {
  my $self = shift;
  $self->{scratch} = $self->pre_process($self->{scratch});
};

after reinit => sub {
  my $self = shift;
  $self->{__buffer} = '';
};

1;
__END__