File Coverage

blib/lib/Message/Passing/Filter/Encoder/JSON.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	7	8	87.5
condition			n/a
subroutine	10	10	100.0
pod	1	1	100.0
total	49	50	98.0

package Message::Passing::Filter::Encoder::JSON;
use Moo;
use MooX::Types::MooseLike::Base qw( Bool HasMethods );
use JSON::MaybeXS qw ();
use Scalar::Util qw/ blessed /;
use Try::Tiny;
use Message::Passing::Exception::Encoding;
use namespace::clean -except => 'meta';

with qw/
    Message::Passing::Role::Filter
    Message::Passing::Role::HasErrorChain
/;

has pretty => (
    isa => Bool,
    default => sub { 0 },
    is => 'ro',
);

has _json => (
    is      => 'lazy',
    isa     => HasMethods [qw( encode )],
    default => sub {
        my $self = shift;
        return JSON::MaybeXS->new( utf8 => 1, pretty => $self->pretty );
    },
);

sub filter {
    my ($self, $message) = @_;
    try {
        return $message unless ref($message);
        if (blessed $message) { # FIXME - This should be moved out of here!
            if ($message->can('pack')) {
                $message = $message->pack;
            }
            elsif ($message->can('to_hash')) {
                $message = $message->to_hash;
            }
        }
        $self->_json->encode( $message );
    }
    catch {
        $self->error->consume(Message::Passing::Exception::Encoding->new(
            exception => $_,
            stringified_data => $message,
        ));
        return; # Explicitly drop the message from normal processing
    }
}

1;

=head1 NAME

Message::Passing::Role::Filter::Encoder::JSON - Encodes data structures as JSON for output

=head1 DESCRIPTION

This filter takes a hash ref or an object for a message, and serializes it to JSON.

Plain refs work as expected, and classes generated by either:

=over

=item Log::Message::Structures

=item MooseX::Storage

=back

should be correctly serialized.

=head1 METHODS

=head2 filter

Performs the JSON encoding.

=head2 pretty

Attribute controlling if JSON is pretty printed.

=head1 SEE ALSO

=over

=item L

=item L

=back

=head1 SPONSORSHIP

This module exists due to the wonderful people at Suretec Systems Ltd.
 who sponsored its development for its
VoIP division called SureVoIP  for use with
the SureVoIP API -


=head1 AUTHOR, COPYRIGHT AND LICENSE

See L.

=cut