File Coverage

blib/lib/Mercury/Pattern/Bus.pm

Criterion	Covered	Total	%
statement	27	28	96.4
branch	4	4	100.0
condition			n/a
subroutine	6	6	100.0
pod	3	3	100.0
total	40	41	97.5

package Mercury::Pattern::Bus;
our $VERSION = '0.014';
# ABSTRACT: A messaging pattern where all peers share messages

#pod =head1 SYNOPSIS
#pod
#pod =head1 DESCRIPTION
#pod
#pod =head1 SEE ALSO
#pod
#pod =cut

use Mojo::Base 'Mojo';

#pod =attr peers
#pod
#pod The list of peers connected to this bus.
#pod
#pod =cut

has peers => sub { [] };

#pod =method add_peer
#pod
#pod     $pat->add_peer( $tx )
#pod
#pod Add the given connection as a peer to this bus.
#pod
#pod =cut

sub add_peer {
    my ( $self, $tx ) = @_;
    $tx->on( message => sub {
        my ( $tx, $msg ) = @_;
        $self->send_message( $msg, $tx );
    } );
    $tx->on( finish => sub {
        my ( $tx ) = @_;
        $self->remove_peer( $tx );
    } );
    push @{ $self->peers }, $tx;
    return;
}

#pod =method remove_peer
#pod
#pod Remove the connection from this bus. Called automatically by the C
#pod handler.
#pod
#pod =cut

sub remove_peer {
    my ( $self, $tx ) = @_;
    my @peers = @{ $self->peers };
    for my $i ( 0.. $#peers ) {
        if ( $peers[$i] eq $tx ) {
            splice @peers, $i, 1;
            return;
        }
    }
    return;
}

#pod =method send_message
#pod
#pod     $pat->send_message( $message, $from )
#pod
#pod Send a message to all the peers on this bus. If a C<$from> websocket is
#pod specified, will not send to that peer (they should know what they sent).
#pod
#pod =cut

sub send_message {
    my ( $self, $msg, $from_tx ) = @_;
    my @peers = @{ $self->peers };
    if ( $from_tx ) {
        @peers = grep { $_ ne $from_tx } @peers;
    }
    $_->send( $msg ) for @peers;
}


1;

__END__