File Coverage

blib/lib/Medical/Growth/Base.pm

Criterion	Covered	Total	%
statement	40	40	100.0
branch	16	16	100.0
condition			n/a
subroutine	7	7	100.0
pod	2	2	100.0
total	65	65	100.0

#!/usr/bin/env perl

use 5.010;
use strict;
use warnings;

package Medical::Growth::Base;

use Scalar::Util qw(openhandle);

our ($VERSION) = '1.00';

sub read_data {
    my ( $callpkg, $file ) = @_;
    my $opened_here = 0;
    my ( $fh, $pos, @lines );
    local ( $., $_ );

    if ( not defined $file ) {
        $callpkg = ref $callpkg if ref $callpkg;
        $fh = do { no strict 'refs'; \*{"${callpkg}::DATA"}; };
        $pos = tell($fh);
    }
    elsif ( openhandle($file) ) {
        $fh = $file;
    }
    else {
        unless ( open $fh, '<', $file ) {
            require Carp;
            Carp::croak("Can't read file \"$file\": $!");
        }
        $opened_here = 1;
    }

    while (<$fh>) {
        last if /^__END__/;

        # Simple comment syntax; we don't allow within line
        # so we don't have to parse for quotes or expressions
        next if /^(?:#.*|\s*)$/;
        push @lines, [split];
    }

    if ($opened_here) {
        close($fh);
    }
    elsif ($pos) {

        # A small twist to restore DATA to initial state when we're done,
        # so it doesn't appear as part of default error messages.
        seek( $fh, $pos, 0 );
    }

    return \@lines;
} ## end sub read_data

sub measure_class_for {
    require Carp;
    Carp::croak("No measure_class_for() method found (called via \"$_[0]\")");
}

1;

__END__