File Coverage

blib/lib/Media/DateTime/JPEG.pm

Criterion	Covered	Total	%
statement	35	38	92.1
branch	8	10	80.0
condition			n/a
subroutine	10	10	100.0
pod	2	2	100.0
total	55	60	91.6

package Media::DateTime::JPEG;

# ABSTRACT: A plugin for the C module to support JPEG files

use strict;
use warnings;

our $VERSION = '0.48';

use Carp;
use Image::ExifTool;
use DateTime;
use Try::Tiny;

my $exifTool;

sub datetime {
    my ( $self, $f ) = @_;

    $exifTool = Image::ExifTool->new() unless $exifTool;
    $exifTool->ExtractInfo($f) or do {
        warn "Exiftool unable to read: $f\nFallback to file timestamp.\n";
        return;
    };

    my $datetime = $exifTool->GetValue('DateTimeOriginal')
      or do {
        warn "JPEG does not contain DateTimeOriginal exif entry ($f),\n"
          . "Fallback to file timestamp.\n";
        return;
      };

    # DateTime format = yyyy:mm:dd hh:mm:ss
    my ( $y, $m, $d, $h, $min, $s ) = $datetime =~ m/
                        (\d{4})  :  # year
                        (\d{2})  :  # month
                        (\d{2})     # day
                            \s      # space
                        (\d{2})  :  # hour
                        (\d{2})  :  # min
                        (\d{2})     # sec
                    /x
      or do {
        warn "failed DateTime pattern match in $f\n"
          . "Fallback to file timestamp";
        return;
      };

    my $date = try {
        DateTime->new(
            year   => $y,
            month  => $m,
            day    => $d,
            hour   => $h,
            minute => $min,
            second => $s,
        );
    }
    catch {
        if (/to DateTime::new did not pass/) {
            warn
              "JPEG's DateTimeOriginal exif entry ($f) not a valid datetime.\n"
              . "Fallback to file timestamp.\n";
            return undef;
        } else {
            die;
        }
    };

    return $date;
}

sub match {
    my ( $self, $f ) = @_;

    return $f =~ /\.jpe?g$/i;    ## no critic
        # TODO: should we use something more complicated here? maybe mime type?
}

1;

__END__