File Coverage

lib/Measure/Everything/Adapter/InfluxDB/Direct.pm

Criterion	Covered	Total	%
statement	24	41	58.5
branch	0	8	0.0
condition	0	5	0.0
subroutine	8	12	66.6
pod	0	2	0.0
total	32	68	47.0

package Measure::Everything::Adapter::InfluxDB::Direct;
use strict;
use warnings;

our $VERSION = '1.000';

# ABSTRACT: Send stats directly to InfluxDB via http

use base qw(Measure::Everything::Adapter::Base);
use InfluxDB::LineProtocol qw(data2line);
use Hijk;
use MIME::Base64 qw/encode_base64/;
use Log::Any qw($log);
use Try::Tiny;

sub init {
    my $self = shift;

    die __PACKAGE__.' required param "host" missing!' unless $self->{host};
    die __PACKAGE__.' required param "db" missing!' unless $self->{db};

    my %args = (
        method       => "POST",
        host         => $self->{host},
        port         => $self->{port} || 8086,
        path         => "/write",
        query_string => "db=" . $self->{db},
    );

    if ($self->{username} && $self->{password}) {
        my $base64 = encode_base64( join( ":", $self->{username}, $self->{password} ) );
        chomp($base64);
        $args{Authorization} = "Basic $base64";
    }

    $self->{_fixed_args} = \%args;
}

sub write {
    my $self = shift;
    my $line = data2line(@_);

    try {
        my $res = Hijk::request({
            %{ $self->{_fixed_args} },
            body         => $line,
        });
        if ( $res->{status} != 204 ) {
            $log->warnf("Could not send line %s to influx: %s",$line, $res->{body});
        }
    }
    catch {
        $log->errorf("Could not reach influx for line %s : %s",$line, $_);
    }
}

1;

__END__