File Coverage

blib/lib/Maven/Artifact.pm

Criterion	Covered	Total	%
statement	47	59	79.6
branch	8	20	40.0
condition	7	17	41.1
subroutine	13	15	86.6
pod	6	6	100.0
total	81	117	69.2

use strict;
use warnings;

package Maven::Artifact;
$Maven::Artifact::VERSION = '1.14';
# ABSTRACT: An maven artifact definition
# PODNAME: Maven::Artifact

use overload
    fallback => 1,
    q{""}    => 'to_string';
use parent qw(Class::Accessor);
__PACKAGE__->follow_best_practice;
__PACKAGE__->mk_accessors(qw(groupId artifactId version classifier artifact_name url));

use Carp qw(croak);
use File::Copy;
use File::Temp;
use Log::Any;

my $logger = Log::Any->get_logger();

sub new {
    my ( $class, @args ) = @_;
    return bless( {}, $class )->_init(@args);
}

sub get_coordinate {
    my ($self) = @_;

    return join( ':',
        $self->get_groupId()    || (),
        $self->get_artifactId() || (),
        $self->get_packaging()  || (),
        $self->get_classifier() || (),
        $self->get_version()    || () );
}

sub get_packaging {
    return shift->{packaging} || 'jar';
}

sub get_uri {
    my ($self) = @_;

    if ( !$self->{uri} ) {
        $self->{uri} = URI->new( $self->{url} );
    }

    return $self->{uri};
}

sub _init {
    my ( $self, $coordinate, %parts ) = @_;

    if ( !( ref($coordinate) eq 'HASH' ) ) {

        # coordinate order is specified per
        # https://maven.apache.org/pom.html#Maven_Coordinates
        my @parts = split( /:/, $coordinate, -1 );
        my $count = scalar(@parts);

        $coordinate = {
            groupId    => $parts[0],
            artifactId => $parts[1]
        };

        # Version could be empty string implying we should detect the latest
        # so dont set it here.
        if ( $count == 3 ) {
            $coordinate->{version} = $parts[2] if ( $parts[2] );
        }
        elsif ( $count == 4 ) {
            $coordinate->{packaging} = $parts[2];
            $coordinate->{version} = $parts[3] if ( $parts[3] );
        }
        elsif ( $count == 5 ) {
            $coordinate->{packaging}  = $parts[2];
            $coordinate->{classifier} = $parts[3] if ( $parts[3] );
            $coordinate->{version}    = $parts[4] if ( $parts[4] );
        }

        foreach my $part ( keys(%parts) ) {

            # only set the part if it has a non-empty value
            my $part_value = $parts{$part};
            if ($part_value) {
                $logger->tracef( 'setting %s to \'%s\'', $part, $part_value );
                $coordinate->{$part} = $part_value;
            }
        }
    }

    $self->{groupId}    = $coordinate->{groupId};
    $self->{artifactId} = $coordinate->{artifactId};
    $self->{version}    = $coordinate->{version};
    $self->{packaging}  = $coordinate->{packaging};
    $self->{classifier} = $coordinate->{classifier};

    return $self;
}

sub set_packaging {
    my ( $self, $packaging ) = @_;
    $self->{packaging} = $packaging;
}

sub to_string {
    return $_[0]->get_coordinate();
}

1;

__END__