File Coverage

blib/lib/Maven/Agent.pm

Criterion	Covered	Total	%
statement	13	15	86.6
branch			n/a
condition			n/a
subroutine	5	5	100.0
pod			n/a
total	18	20	90.0

use strict;
use warnings;

package Maven::Agent;
$Maven::Agent::VERSION = '1.14';
# ABSTRACT: A base agent for working with maven
# PODNAME: Maven::Agent

use Carp qw(croak);
use File::Copy;
use Maven::Maven;

sub new {
    return bless( {}, shift )->_init(@_);
}

sub download {
    my ( $self, $artifact, %options ) = @_;

    if (   !ref($artifact)
        || !$artifact->isa('Maven::Artifact')
        || !$artifact->get_uri() )
    {
        $artifact = $self->resolve_or_die($artifact);
    }

    if ( $self->is_local($artifact) ) {
        my $path = $artifact->get_uri()->path();
        if ( $options{to} ) {
            my $file = _to_file( $options{to}, $artifact );
            if ( $file ne $path ) {
                copy( $path, $file );
                $path = $file;
            }
        }
        return $path;
    }

    return $self->_download_remote( $artifact, $options{to}
        ? _to_file( $options{to}, $artifact )
        : () );
}

sub _default_agent {
    my ( $self, @options ) = @_;
    require LWP::UserAgent;
    my $agent = LWP::UserAgent->new(@options);
    $agent->env_proxy();    # because why not?
    return $agent;
}

sub _download_remote {
    my ( $self, $artifact, $file ) = @_;

    $file ||= Maven::Agent::DownloadedFile->new();

    $self->{agent}->get( $artifact->get_uri(), ':content_file' => "$file" );

    return $file;
}

sub get_maven {
    return shift->{maven};
}

sub _init {
    my ( $self, %options ) = @_;

    $options{agent} = $self->_default_agent(%options)
        unless ( $options{agent} );

    $self->{agent} = $options{agent};
    $self->{maven} = Maven::Maven->new(%options);

    return $self;
}

sub is_local {
    my ( $self, $artifact ) = @_;
    my $uri = $artifact->get_uri();
    return ( $uri->scheme() =~ /^file$/i
            && ( $uri->host() eq '' || $uri->host() =~ /^localhost$/ ) );
}

sub resolve {
    return shift->{maven}->get_repositories()->resolve(@_);
}

sub resolve_or_die {
    return shift->{maven}->get_repositories()->resolve_or_die(@_);
}

sub _to_file {
    my ( $to, $artifact ) = @_;
    if ( -d $to ) {
        $to = File::Spec->catfile( $to, "$artifact->{artifactId}." . $artifact->get_packaging() );
    }
    return $to;
}

package Maven::Agent::DownloadedFile;
$Maven::Agent::DownloadedFile::VERSION = '1.14';
# Wraps a temp file to hold a reference so as to keep the destructor from
# getting called.  It will provide the filename when used as a string.

use overload q{""} => 'filename', fallback => 1;

sub new {
    my $self = bless( {}, shift );
    my $file = File::Temp->new();

    $self->{handle} = $file;
    $self->{name}   = $file->filename();

    return $self;
}

sub filename {
    return $_[0]->{name};
}

1;

__END__