File Coverage

blib/lib/Math/Shape/LineSegment.pm

Criterion	Covered	Total	%
statement	47	48	97.9
branch	19	22	86.3
condition			n/a
subroutine	10	10	100.0
pod	3	3	100.0
total	79	83	95.1

use strict;
use warnings;
package Math::Shape::LineSegment;
$Math::Shape::LineSegment::VERSION = '0.13';
use 5.008;
use Carp;
use Math::Shape::Vector;
use Math::Shape::Range;
use Math::Shape::Line;

# ABSTRACT: a 2d vector line segment; a line with start and end points


sub new {
    croak 'incorrect number of args' unless @_ == 5;
    my ($class, $x1, $y1, $x2, $y2) = @_;
    bless { start => Math::Shape::Vector->new($x1, $y1),
            end   => Math::Shape::Vector->new($x2, $y2),
          }, $class;
}


sub project
{
    croak 'project not called with argument of type Math::Shape::Vector' unless $_[1]->isa('Math::Shape::Vector');
    my ($self, $vector) = @_;
    my $unit_vector = $vector->convert_to_unit_vector;

    my $range = Math::Shape::Range->new(
        $unit_vector->dot_product($self->{start}),
        $unit_vector->dot_product($self->{end}),
    );

    $range->sort;
}


sub collides
{
    my ($self, $other_obj) = @_;

    if ($other_obj->isa('Math::Shape::LineSegment'))
    {
        my $vector_a = $self->{end}->subtract_vector($self->{start});
        my $axis_a = Math::Shape::Line->new(
            $self->{start}->{x},
            $self->{start}->{y},
            $vector_a->{x},
            $vector_a->{y});

        return 0 if $axis_a->on_one_side($other_obj);

        my $vector_b = $other_obj->{end}->subtract_vector($other_obj->{start});
        my $axis_b = Math::Shape::Line->new(
            $other_obj->{start}->{x},
            $other_obj->{start}->{y},
            $vector_b->{x},
            $vector_b->{y});

        return 0 if $axis_b->on_one_side($self);

        if ($axis_a->{direction}->is_parallel($axis_b->{direction}))
        {
            my $range_a = $self->project($axis_a->{direction});
            my $range_b = $other_obj->project($axis_a->{direction});
            return $range_a->is_overlapping($range_b);
        }

        1;
    }
    elsif ($other_obj->isa('Math::Shape::Vector'))
    {
        $other_obj->collides($self);
    }
    elsif ($other_obj->isa('Math::Shape::Line'))
    {
        $other_obj->collides($self);
    }
    elsif ($other_obj->isa('Math::Shape::OrientedRectangle'))
    {
        $other_obj->collides($self);
    }
    elsif ($other_obj->isa('Math::Shape::Rectangle'))
    {
        $other_obj->collides($self);
    }
    elsif ($other_obj->isa('Math::Shape::Circle'))
    {
        $other_obj->collides($self);
    }
    else
    {
        croak 'collides must be called with a Math::Shape::Vector library object';
    }
}

1;

__END__