File Coverage

blib/lib/Math/SNAFU.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	6	6	100.0
condition	1	3	33.3
subroutine	7	7	100.0
pod	2	2	100.0
total	49	51	96.0

use 5.012;
use strict;
use warnings;

package Math::SNAFU;

our $AUTHORITY = 'cpan:TOBYINK';
our $VERSION   = '0.001';

use Carp qw(
	croak
);

use Exporter::Shiny 1.006000 qw(
	decimal_to_snafu
	snafu_to_decimal
);

sub decimal_to_snafu ($) {
	my ( $n ) = @_;
	return '0' if $n == 0;

	my @chars;
	while ( $n > 0 ) {
		my $mod = $n % 5;
		$n = int( $n / 5 );
		if ( $mod == 3 ) {
			push @chars, '=';
			++$n;
		}
		elsif ( $mod == 4 ) {
			push @chars, '-';
			++$n;
		}
		else {
			push @chars, $mod;
		}
	}

	return join '', reverse @chars;
}

sub snafu_to_decimal ($) {
	my ( $snafu ) = @_;

	state $digits = {
		'='  => -2,
		'-'  => -1,
		'0'  => +0,
		'1'  => +1,
		'2'  => +2,
	};

	my @input = reverse split //, $snafu;
	my ( $sum, $slot ) = ( 0, 0 );
	$sum += ( 5 ** $slot++ ) * ( $digits->{$_} // croak "Bad SNAFU digit: $_" )
		for @input;

	return $sum;
}

1;

__END__