File Coverage

blib/lib/Math/PlanePath/ComplexMinus.pm

Criterion	Covered	Total	%
statement	74	138	53.6
branch	8	38	21.0
condition	5	6	83.3
subroutine	13	22	59.0
pod	11	11	100.0
total	111	215	51.6

# Copyright 2011, 2012, 2013, 2014, 2015, 2016, 2017, 2018, 2019 Kevin Ryde

# This file is part of Math-PlanePath.
#
# Math-PlanePath is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by the
# Free Software Foundation; either version 3, or (at your option) any later
# version.
#
# Math-PlanePath is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
# or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
# for more details.
#
# You should have received a copy of the GNU General Public License along
# with Math-PlanePath.  If not, see .


# math-image --path=ComplexMinus --lines --scale=10
# math-image --path=ComplexMinus --all --output=numbers_dash --size=80x50

# Penney numerals in tcl
# http://wiki.tcl.tk/10761

# cf A003476 = boundary length of i-1 ComplexMinus
# is same as DragonCurve single points N=0 to N=2^k inclusive

# Mandelbrot "Fractals: Form, Chance and Dimension"
# distance along the boundary between any two points is infinite

# Fractal Tilings Derived from Complex Bases
# Sara Hagey and Judith Palagallo
# The Mathematical Gazette
# Vol. 85, No. 503 (Jul., 2001), pp. 194-201
# Published by: The Mathematical Association
# Article Stable URL: http://www.jstor.org/stable/3622004

# cf http://szdg.lpds.sztaki.hu/szdg/desc_numsys_es.php
# in more than 2 dimensions, by vectors and matrix multiply


package Math::PlanePath::ComplexMinus;
use 5.004;
use strict;
use List::Util 'min';
#use List::Util 'max';
*max = \&Math::PlanePath::_max;

use vars '$VERSION', '@ISA';
$VERSION = 127;
use Math::PlanePath;
@ISA = ('Math::PlanePath');

use Math::PlanePath::Base::Generic
  'is_infinite',
  'round_nearest';
use Math::PlanePath::Base::Digits
  'round_up_pow',
  'digit_split_lowtohigh',
  'digit_join_lowtohigh';

# uncomment this to run the ### lines
# use Smart::Comments;


use constant n_start => 0;

use constant parameter_info_array =>
  [ { name        => 'realpart',
      display     => 'Real Part',
      type        => 'integer',
      default     => 1,
      minimum     => 1,
      width       => 2,
      description => 'Real part r in the i-r complex base.',
    } ];


sub x_negative_at_n {
  my ($self) = @_;
  return $self->{'norm'};
}
sub y_negative_at_n {
  my ($self) = @_;
  return $self->{'norm'} ** 2;
}

sub absdx_minimum {
  my ($self) = @_;
  return ($self->{'realpart'} == 1
          ? 0   # i-1 N=3 dX=0,dY=-3
          : 1); # i-r otherwise always diff
}

# realpart=1
# dx=1,1,0,0,1,1,0,0,1,1,0,0,1,1,0,0,1,1,0 = (6*16^k-2)/15
# dy=1,0,0,1,1,0,0,1,1,0,0,1,1,0,0,1,1,0,1 = ((9*16^5-1)/15-1)/2+1
# approaches dx=6/15=12/30, dy=9/15/2=9/30

# FIXME: are others smaller than East ?
sub dir_maximum_dxdy {
  my ($self) = @_;
  if ($self->{'realpart'} == 1) { return (12,-9); }
  else { return (0,0); }
}

sub turn_any_straight {
  my ($self) = @_;
  return ($self->{'realpart'} != 1);  # realpart=1 never straight
}


#------------------------------------------------------------------------------
sub new {
  my $self = shift->SUPER::new(@_);

  my $realpart = $self->{'realpart'};
  if (! defined $realpart || $realpart < 1) {
    $self->{'realpart'} = $realpart = 1;
  }
  $self->{'norm'} = $realpart*$realpart + 1;
  return $self;
}

sub n_to_xy {
  my ($self, $n) = @_;
  ### ComplexMinus n_to_xy(): $n

  if ($n < 0) { return; }
  if (is_infinite($n)) { return ($n,$n); }

  # is this sort of midpoint worthwhile? not documented yet
  {
    my $int = int($n);
    ### $int
    ### $n
    if ($n != $int) {
      my ($x1,$y1) = $self->n_to_xy($int);
      my ($x2,$y2) = $self->n_to_xy($int+1);
      my $frac = $n - $int;  # inherit possible BigFloat
      my $dx = $x2-$x1;
      my $dy = $y2-$y1;
      return ($frac*$dx + $x1, $frac*$dy + $y1);
    }
    $n = $int;       # BigFloat int() gives BigInt, use that
  }

  my $x = 0;
  my $y = 0;
  my $dy = ($n * 0);   # 0, inherit bignum from $n
  my $dx = $dy + 1;    # 1, inherit bignum from $n
  my $realpart = $self->{'realpart'};
  my $norm = $self->{'norm'};

  foreach my $digit (digit_split_lowtohigh($n,$norm)) {
    ### at: "$x,$y  digit=$digit"

    $x += $digit * $dx;
    $y += $digit * $dy;

    # multiply i-r, ie. (dx,dy) = (dx + i*dy)*(i-$realpart)
    ($dx,$dy) = (-$dy - $realpart*$dx,
                 $dx - $realpart*$dy);
  }
# GP-Test  (dx+I*dy)*(I-'r) == -dy - 'r*dx  + I*(dx - 'r*dy)

  ### final: "$x,$y"
  return ($x,$y);
}

sub xy_to_n {
  my ($self, $x, $y) = @_;
  ### ComplexMinus xy_to_n(): "$x, $y"

  $x = round_nearest ($x);
  $y = round_nearest ($y);

  my $realpart = $self->{'realpart'};
  {
    my $rx = $realpart*$x;
    my $ry = $realpart*$y;
    foreach my $overflow ($rx+$ry, $rx-$ry) {
      if (is_infinite($overflow)) { return $overflow; }
    }
  }

  my $norm = $self->{'norm'};
  my $zero = ($x * 0 * $y);  # inherit bignum 0
  my @n; # digits low to high

  while ($x || $y) {
    my $new_y = $y*$realpart + $x;

    my $digit = $new_y % $norm;
    push @n, $digit;

    $x -= $digit;
    $new_y = $digit - $new_y;

    # div i-realpart,
    # is (i*y + x) * -(i+realpart)/norm
    #  x = [ x*realpart - y ] / -norm
    #    = [ y - x*realpart ] / norm
    #  y = - [ y*realpart + x ] / norm
    #

    ### assert: (($y - $x*$realpart) % $norm) == 0
    ### assert: ($new_y % $norm) == 0

    ($x,$y) = (($y - $x*$realpart) / $norm,
               $new_y / $norm);
  }
  return digit_join_lowtohigh (\@n, $norm, $zero);
}

# for i-1 need level=6 to cover 8 points surrounding 0,0
# for i-2 and higher level=3 is enough

# not exact
sub rect_to_n_range {
  my ($self, $x1,$y1, $x2,$y2) = @_;
  ### ComplexMinus rect_to_n_range(): "$x1,$y1  $x2,$y2"

  my $xm = max(abs($x1),abs($x2));
  my $ym = max(abs($y1),abs($y2));

  return (0,
          int (($xm*$xm + $ym*$ym)
               * $self->{'norm'} ** ($self->{'realpart'} > 1
                                     ? 4
                                     : 8)));
}

#------------------------------------------------------------------------------

sub _UNDOCUMENTED_level_to_figure_boundary {
  my ($self, $level) = @_;
  ### _UNDOCUMENTED_level_to_figure_boundary(): "level=$level realpart=$self->{'realpart'}"

  if ($level < 0) { return undef; }
  if (is_infinite($level)) { return $level; }

  my $b0 = 4;
  if ($level == 0) { return $b0; }

  my $norm = $self->{'norm'};
  my $b1 = 2*$norm + 2;
  if ($level == 1) { return $b1; }

  # 2*(norm-1)*(realpart + 2) + 4;
  # = 2*(n*r + 2*n -r - 2) + 4
  # = 2*n*r + 4n -2r - 4 + 4
  # = 2*n*r + 4n -2r
  my $realpart = $self->{'realpart'};
  my $b2 = 2*($norm-1)*($realpart + 2) + 4;

  my $f1 = $norm - 2*$realpart;
  my $f2 = 2*$realpart - 1;
  foreach (3 .. $level) {
    ($b2,$b1,$b0) = ($f2*$b2 + $f1*$b1 + $norm*$b0, $b2, $b1);
  }
  return $b2;
}

#------------------------------------------------------------------------------

{
  my @table = ('','');
  # 6-bit blocks per Penney
  foreach my $i (064,067,060,063, 4,7,0,3) { vec($table[0],$i,1) = 1; }
  foreach my $i (020,021,034,035, 0,1,014,015) { vec($table[1],$i,1) = 1; }

  sub _UNDOCUMENTED__n_is_y_axis {
    my ($self, $n) = @_;
    if (is_infinite($n)) { return 0; }
    if ($n < 0) { return 0; }

    if ($self->{'realpart'} == 1) {
      my $pos = 0;
      foreach my $digit (digit_split_lowtohigh($n,64)) {
        unless (vec($table[$pos&1],$digit,1)) {
          ### bad digit: "pos=$pos digit=$digit"
          return 0;
        }
        $pos++;
      }
      ### good ...
      return 1;

    } else {
      my ($x,$y) = $self->n_to_xy($n)
        or return 0;
      return $x == 0;
    }
  }
}

#------------------------------------------------------------------------------
# levels

sub level_to_n_range {
  my ($self, $level) = @_;
  return (0, $self->{'norm'}**$level - 1);
}
sub n_to_level {
  my ($self, $n) = @_;
  if ($n < 0) { return undef; }
  if (is_infinite($n)) { return $n; }
  $n = round_nearest($n);
  my ($pow, $exp) = round_up_pow ($n+1, $self->{'norm'});
  return $exp;
}


#------------------------------------------------------------------------------
1;
__END__