File Coverage

blib/lib/Math/ModInt/Event.pm

Criterion	Covered	Total	%
statement	63	63	100.0
branch			n/a
condition	2	2	100.0
subroutine	22	22	100.0
pod	4	4	100.0
total	91	91	100.0

# Copyright (c) 2010-2019 Martin Becker, Blaubeuren.
# This package is free software; you can distribute it and/or modify it
# under the terms of the Artistic License 2.0 (see LICENSE file).

package Math::ModInt::Event;

use 5.006;
use strict;
use warnings;
use Carp qw(croak);
use Math::ModInt::Event::Trap;

# ----- class data -----

BEGIN {
    require Exporter;
    our @ISA        = qw(Exporter);
    our @EXPORT_OK  = qw(
        AnyEvent Unrecoverable Recoverable UsageError Nonexistent
        LoadingFailure UndefinedResult DifferentModuli
    );
    our @CARP_NOT   = qw(Math::ModInt);
    our $VERSION    = '0.012';
}

# Math::ModInt::Event=ARRAY(...)

# ............ index ............   # ............ value ............
use constant F_DESCRIPTION  => 0;   # a short event description string
use constant NFIELDS        => 1;

# ----- private subroutines -----

# create a new event subclass and return a singleton instance of that class
# - description string is made of the words in the camel-case class name
# - parent class is taken from optional parent object or defaults to Event.
sub _make {
    my ($class, $parent) = @_;
    my $description = lc join q[ ], split /(?<=[a-z])(?=[A-Z])/, $class;
    $class  = join '::', __PACKAGE__, $class;
    eval join '', '@', $class, '::ISA = qw(', ref $parent || __PACKAGE__, ')';
    return bless [$description], $class;
}

# ----- public methods -----

# singleton event constructors:

use constant AnyEvent            => _make('AnyEvent');
use constant   Unrecoverable     => _make('Unrecoverable',   AnyEvent);
use constant     UsageError      => _make('UsageError',      Unrecoverable);
use constant     Nonexistent     => _make('Nonexistent',     Unrecoverable);
use constant     LoadingFailure  => _make('LoadingFailure',  Unrecoverable);
use constant   Recoverable       => _make('Recoverable',     AnyEvent);
use constant     UndefinedResult => _make('UndefinedResult', Recoverable);
use constant     DifferentModuli => _make('DifferentModuli', Recoverable);

sub description {
    my ($this) = @_;
    return $this->[F_DESCRIPTION];
}

sub is_recoverable { 0 }
sub Math::ModInt::Event::Recoverable::is_recoverable { 1 }

sub trap {
    my ($this, $handler) = @_;
    return Math::ModInt::Event::Trap->new($this, $handler);
}

sub raise {
    my ($this, @details) = @_;
    Math::ModInt::Event::Trap->broadcast($this, @details);
    return $this;
}

1;

__END__