File Coverage

blib/lib/Math/ModInt/GF2.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	10	10	100.0
condition	3	3	100.0
subroutine	18	18	100.0
pod	3	3	100.0
total	77	77	100.0

# Copyright (c) 2009-2015 Martin Becker.  All rights reserved.
# This package is free software; you can redistribute it and/or modify it
# under the same terms as Perl itself.
#
# $Id: GF2.pm 60 2015-05-18 08:47:12Z demetri $

package Math::ModInt::GF2;

use 5.006;
use strict;
use warnings;

# ----- object definition -----

# Math::ModInt::GF2=ARRAY(...)

# .......... index ..........   # .......... value ..........
use constant F_RESIDUE => 0;    # residue r, either 0 or 1
use constant NFIELDS   => 1;

# ----- class data -----

BEGIN {
    require Math::ModInt;
    our @ISA     = qw(Math::ModInt);
    our $VERSION = '0.011';
}

my @base = map { bless [$_] } 0..1;     # singletons

# ----- private methods -----

sub _NEG { $_[0] }

sub _ADD {
    my ($this, $that) = @_;
    return $base[$this->[F_RESIDUE] ^ $that->[F_RESIDUE]];
}

sub _SUB {
    my ($this, $that) = @_;
    return $base[$this->[F_RESIDUE] ^ $that->[F_RESIDUE]];
}

sub _MUL {
    my ($this, $that) = @_;
    return $base[$this->[F_RESIDUE] & $that->[F_RESIDUE]];
}

sub _DIV {
    my ($this, $that) = @_;
    return $that->[F_RESIDUE]? $this: Math::ModInt->undefined;
}

sub _POW {
    my ($this, $exp) = @_;
    return
        $this->[F_RESIDUE] || $exp > 0? $this:
        $exp? $this->undefined: $base[1];
}

sub _INV {
    my ($this) = @_;
    return $this->[F_RESIDUE]? $this: Math::ModInt->undefined;
}

sub _NEW {
    my ($this, $int) = @_;
    return $base[$int & 1];
}

sub _NEW2 {
    my ($this, $int) = @_;
    if ($int < 0) {
        # no arithmetic shift operation for negative perl integers, alas
        my $residue = $int & 1;
        return (($int - $residue) / 2, $base[$residue]);
    }
    return ($int >> 1, $base[$int & 1]);
}

sub residue {
    my ($this) = @_;
    return $this->[F_RESIDUE];
}

sub centered_residue {
    my ($this) = @_;
    return $this->[F_RESIDUE];
}

sub modulus {
    return 2;
}

1;

__END__