File Coverage

blib/lib/Math/Int2Base.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	4	4	100.0
condition	23	27	85.1
subroutine	9	9	100.0
pod	0	3	0.0
total	75	82	91.4

package Math::Int2Base;

use 5.008006;
use strict;
use warnings;
use Carp;

our $VERSION = '1.01';

require Exporter;
use base qw(Exporter);

our @EXPORT_OK = qw( int2base base2int base_chars );

my @Chars   = ('0'..'9', 'A'..'Z', 'a'..'z');
my $MaxBase = scalar @Chars;
my $CharStr = join '', @Chars;

#---------------------------------------------------------------------
# int2base( $num, $base, $minlen );  # base ||= 10 minlen ||= 1
sub int2base {

    my( $ret, $num, $base, $minlen ) = ( '', @_ );
    $num    ||= 0;
    $base   ||= 10;
    $minlen ||= 1;

    if( $num        < 0
        || $base    < 2
        || $MaxBase < $base
        || $minlen  < 1
        # || $num    != int( $num )  # XXX[1] do we care?
        ) {
        croak "not supported: int2base( '$num', $base, $minlen )" }

    for (; $num; $num = int($num/$base) ) { $ret .= $Chars[$num % $base] }
    no warnings 'numeric';  # negative repeat count
    return scalar reverse $ret . '0'x($minlen - length($ret));
}

#---------------------------------------------------------------------
# base2int( $num, $base );  # base ||= 10
sub base2int {

    my( $ret, $num, $base ) = ( 0, @_ );
    $num    ||= 0;
    $base   ||= 10;
    my $chars = substr $CharStr, 0, $base;

    if( $num       !~ /^[$chars]+$/
        || $base    <  2
        || $MaxBase <  $base         ) {
        croak "not supported: base2int( '$num', $base )" }

    $num =~ s/^0+//;  # trim leading zeros
    for( my $i = length($num)-1, my $c = 0; $i >= 0; --$i ) {
        $ret += index($CharStr, substr($num, $i, 1)) * $base**$c++ }
    return $ret;
}

#---------------------------------------------------------------------
# base_chars( $base );  # base ||= 10
sub base_chars {
    my( $base ) = @_;
    $base ||= 10;
    return substr $CharStr, 0, $base;
}

1;
__END__