File Coverage

blib/lib/Math/BigInt/Named.pm

Criterion	Covered	Total	%
statement	44	49	89.8
branch	19	28	67.8
condition			n/a
subroutine	6	7	85.7
pod	2	2	100.0
total	71	86	82.5

#!perl

package Math::BigInt::Named;

use 5.006001;
use strict;
use warnings;

use Carp qw( carp croak );

use Math::BigInt 1.97;
our @ISA = qw(Math::BigInt);

our $VERSION = '0.07';

# Globals.

our ($accuracy, $precision, $round_mode, $div_scale);
$accuracy   = undef;
$precision  = undef;
$round_mode = 'even';
$div_scale  = 40;

# Not all of them exist yet.
my $LANGUAGE = {
  en => 'english',
  de => 'german',
  sp => 'spanish',
  fr => 'french',
  ro => 'romana',
  it => 'italian',
  no => 'norwegian',
  };

# Index of languages that have been loaded.

my $LOADED = { };

sub name {
    # output the name of the number
    my $x = shift;

    # make Math::BigInt::Name -> name(123) work
    $x = $x -> new(shift) unless ref($x);

    return 'NaN' if $x -> is_nan();

    my @args = ();
    if (@_) {
        if (ref($_[0]) eq 'HASH') {
            carp "When the options are given as a hash ref, additional",
              " arguments are ignored" if @_ > 1;
            @args = %{ $_[0] };
        } else {
            @args = @_;
        }
    }

    my $lang;
    while (@args) {
        my $param = shift @args;
        croak "Parameter name can not be undefined" unless defined $param;
        croak "Parameter name can not be an empty string" unless length $param;

        if ($param =~ /^lang(uage)?$/) {
            $lang = shift @args;
            croak "Language can not be undefined" unless defined $lang;
            croak "Language can not be an empty string" unless length $lang;
            next;
        }

        croak "Invalid parameter '$param'";
    }

    $lang = 'english' unless defined $lang;
    $lang = $LANGUAGE -> {$lang} if exists $LANGUAGE -> {$lang}; # en => english

    $lang = 'Math::BigInt::Named::' . ucfirst($lang);

    if (!defined $LOADED -> {$lang}) {
        my $file = $lang;
        $file =~ s|::|/|g;
        $file .= ".pm";
        eval { require $file; };
        croak $@ if $@;
        $LOADED -> {$lang} = 1;
    }

    my $y = $lang -> new($x);
    $y -> name();
}

sub from_name {
    # Create a Math::BigInt::Name from a name string. Not implemented.

    my $x = Math::BigInt -> bnan();
}

1;

__END__