File Coverage

blib/lib/Math/Base36.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	10	10	100.0
condition	2	2	100.0
subroutine	7	7	100.0
pod	2	2	100.0
total	54	54	100.0

package Math::Base36;

use strict;
use warnings;

use base qw( Exporter );

use Carp 'croak';
use Math::BigInt ();

our %EXPORT_TAGS = ( 'all' => [ qw(encode_base36 decode_base36) ] );
our @EXPORT_OK = ( @{ $EXPORT_TAGS{ 'all' } } );

our $VERSION = '0.13';

sub decode_base36 {
    my $base36 = uc( shift );
    croak "Invalid base36 number ($base36)" if $base36 =~ m{[^0-9A-Z]};

    my ( $result, $digit ) = ( 0, 0 );
    for my $char ( split( //, reverse $base36 ) ) {
        my $value = $char =~ m{\d} ? $char : ord( $char ) - 55;
        $result += $value * Math::BigInt->new( 36 )->bpow( $digit++ );
    }

    return $result;
}

sub encode_base36 {
    my ( $number, $padlength ) = @_;
    $padlength ||= 1;

    croak "Invalid base10 number ($number)"  if $number    =~ m{\D};
    croak "Invalid padding length ($padlength)" if $padlength =~ m{\D};

    $number = Math::BigInt->new( $number );
    my $result = '';
    while ( $number ) {
        my $remainder = $number % 36;
        $result .= $remainder <= 9 ? $remainder : chr( 55 + $remainder );
        $number = int $number / 36;
    }

    return '0' x ( $padlength - length $result ) . reverse( $result );
}

1;

__END__