File Coverage

blib/lib/MarpaX/Languages/C/AST/Grammar/ISO_ANSI_C_2011.pm

Criterion	Covered	Total	%
statement	53	58	91.3
branch	9	16	56.2
condition	4	12	33.3
subroutine	9	9	100.0
pod	4	4	100.0
total	79	99	79.8

use strict;
use warnings FATAL => 'all';

package MarpaX::Languages::C::AST::Grammar::ISO_ANSI_C_2011;
use MarpaX::Languages::C::AST::Grammar::ISO_ANSI_C_2011::Actions;
use Carp qw/croak/;
use IO::String;

# ABSTRACT: ISO ANSI C 2011 grammar written in Marpa BNF

our $VERSION = '0.47'; # VERSION


our %DEFAULT_PAUSE = (
    TYPEDEF_NAME         => 'before',
    ENUMERATION_CONSTANT => 'before',
    IDENTIFIER           => 'before',
    SEMICOLON            => 'after',
    LCURLY_SCOPE         => 'after',
    LCURLY_REENTERSCOPE  => 'after',
    RCURLY_SCOPE         => 'after',
    COMMA                => 'after',
    EQUAL                => 'after',
    LPAREN_SCOPE         => 'after',
    RPAREN_SCOPE         => 'after',
    ANY_ASM              => 'after',
);

our $DEFAULTACTIONOBJECT = sprintf('%s::%s', __PACKAGE__, 'Actions');
our $DEFAULTNONTERMINALSEMANTIC = ':default ::= action => [values] bless => ::lhs';
our $DEFAULTTERMINALSEMANTIC = 'lexeme default = action => [start,length,value,name] forgiving => 1';

our $DATA = do {local $/; };

sub new {
  my ($class, $pausep, $start, $actionObject, $nonTerminalSemantic, $terminalSemantic) = @_;

  $actionObject //= $DEFAULTACTIONOBJECT;

  my $self  = {
    _grammar_option => {},
    _recce_option => {semantics_package => $actionObject, ranking_method => 'high_rule_only'},
  };
  #
  # Rework the grammar to have the pauses:
  # Those in %DEFAULT_PAUSE cannot be altered.
  # The other lexemes given in argument will get a pause => after eventually
  #
  my %pause = ();
  if (defined($pausep)) {
      if (ref($pausep) ne 'HASH') {
        croak 'pausep must be a reference to HASH';
      }
      map {$pause{$_} = 'after'} keys %{$pausep};
  }
  map {$pause{$_} = $DEFAULT_PAUSE{$_}} keys %DEFAULT_PAUSE;

  $self->{_content} = '';
  my $allb = exists($pause{__ALL__});
  my $pragmas = '';
  if (defined($start) && "$start") {
    #
    # User gave a custom start, we assume he will hit inaccessible symbols
    #
    $pragmas = "\ninaccessible is ok by default\n";
  } else {
    $start = 'translationUnit';
  }
  my $data = IO::String->new($DATA);
  while (defined($_ = <$data>)) {
      my $line = $_;
      if ($line =~ /^\s*:lexeme\s*~\s*<(\w+)>/) {
        my $lexeme = substr($line, $-[1], $+[1] - $-[1]);
        #
        # Doing this test first will make sure DEFAULT_PAUSE lexemes
        # will always get the correct 'pause' value (i.e. after or before)
        #
        if (exists($pause{$lexeme})) {
          if (! ($line =~ /\bpause\b/)) {
            substr($line, -1, 1) = " pause => $pause{$lexeme}\n";
          }
        } elsif ($allb) {
            if (! ($line =~ /\bpause\b/)) {
              #
              # Hardcoded to 'after'
              #
              substr($line, -1, 1) = " pause => after\n";
            }
          }
      }
      $self->{_content} .= $line;
  }
  $nonTerminalSemantic //= $DEFAULTNONTERMINALSEMANTIC;
  $terminalSemantic //= $DEFAULTTERMINALSEMANTIC;

  $self->{_content} =~ s/\$PRAGMAS\n/$pragmas/;
  $self->{_content} =~ s/\$START\n/$start/;
  $self->{_content} =~ s/\$NONTERMINALSEMANTIC\b/$nonTerminalSemantic/;
  $self->{_content} =~ s/\$TERMINALSEMANTIC\b/$terminalSemantic/;

  bless($self, $class);

  return $self;
}


sub content {
    my ($self) = @_;
    return $self->{_content};
}


sub grammar_option {
    my ($self) = @_;
    return $self->{_grammar_option};
}


sub recce_option {
    my ($self) = @_;
    return $self->{_recce_option};
}

1;

=pod

=encoding UTF-8

=head1 NAME

MarpaX::Languages::C::AST::Grammar::ISO_ANSI_C_2011 - ISO ANSI C 2011 grammar written in Marpa BNF

=head1 VERSION

version 0.47

=head1 SYNOPSIS

    use strict;
    use warnings FATAL => 'all';
    use MarpaX::Languages::C::AST::Grammar::ISO_ANSI_C_2011;

    my $grammar = MarpaX::Languages::C::AST::Grammar::ISO_ANSI_C_2011->new();

    my $grammar_content = $grammar->content();
    my $grammar_option = $grammar->grammar_option();
    my $recce_option = $grammar->recce_option();

=head1 DESCRIPTION

This modules contains the ISO ANSI C 2011 C grammar written in Marpa BNF, as of L and L.

=head1 SUBROUTINES/METHODS

=head2 new([$pausep, $start, $actionObject, $nonTerminalSemantic, $terminalSemantic])

Instance a new object. Takes an eventual reference to a HASH for lexemes for which a pause after is requested, followed by an eventual start rule, an eventual action object, an eventual default non-terminal semantic action, a default terminal semantic action. Default paused lexemes is hardcoded to a list of lexeme that must always be paused, and this list cannot be altered. Default start rule is 'translationUnit'. Default action object is hardcoded to __PACKAGE__::Actions module. Default non-terminal semantic is hardcoded to ':default ::= action => [values] bless => ::lhs'. Default terminal semantic is hardcoded to :'lexeme default = action => [start,length,value] forgiving => 1'.

=head2 content()

Returns the content of the grammar. Takes no argument.

=head2 grammar_option()

Returns recommended option for Marpa::R2::Scanless::G->new(), returned as a reference to a hash.

=head2 recce_option()

Returns recommended option for Marpa::R2::Scanless::R->new(), returned as a reference to a hash.

=head1 AUTHOR

Jean-Damien Durand

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2013 by Jean-Damien Durand.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut

__DATA__