File Coverage

blib/lib/Markdown/Table.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	3	4	75.0
condition	3	4	75.0
subroutine	8	8	100.0
pod	4	4	100.0
total	66	68	97.0

package Markdown::Table;

# ABSTRACT: Create and parse tables in Markdown

use strict;
use warnings;

use Moo;

use Text::ASCIITable 0.22;

our $VERSION = 0.03;

has cols => (
    is  => 'rwp',
    isa => sub { ref $_[0] and 'ARRAY' eq ref $_[0] },
);

has rows => (
    is  => 'rwp',
    isa => sub { ref $_[0] and 'ARRAY' eq ref $_[0] },
);

sub parse {
    my ($class, $markdown, $options) = @_;

    $options //= {};

    my @found_tables = $markdown =~ m{
        (
            ^\|[^\n]+\n
            ^\|(?:-{3,}\|)+\n
            (?:
                ^\|[^\n]+\n
            )+
        )
    }xmg;

    if ( $options->{nuclino} ) {
        push @found_tables, $markdown =~ m{
            ^\+(?:-+\+)+\n
            (
                (?:
                    ^\|[^\n]+\n
                    (?:^(?:\+(?:-+\+)+)\n)?
                )+
            )
            ^(?:\+(?:-+\+)+)
        }xmsg;
    }


    my @tables;

    for my $table ( @found_tables ) {
        my @lines = grep{ $_ =~ m{\A\|[^-]+} } split /\n/, $table;

        my $headerline = shift @lines;
        $headerline    =~ s{\A\|\s+}{};
        $headerline    =~ s{\s+\|$}{};
        my @cols       = split /\s+\|\s+/, $headerline;

        my @rows = map{
            $_ =~ s{\A\|\s+}{};
            $_ =~ s{\s+\|$}{};
            [ split /\s+\|\s+/, $_ ];
        } @lines;

        push @tables, $class->new(
            cols => \@cols,
            rows => \@rows,
        );
    }

    return @tables;
}

sub set_cols {
    my ($self, @cols) = @_;

    $self->_set_cols( \@cols );
    return $self->cols;
}

sub add_rows {
    my ($self, @new_rows) = @_;

    my $rows = $self->rows || [];
    push @{ $rows }, @new_rows;
    $self->_set_rows( $rows );

    return $rows;
}

sub get_table {
    my ($self) = @_;

    my $ascii = Text::ASCIITable->new({
        hide_LastLine => 1,
        hide_FirstLine => 1,
    });

    $ascii->setCols( $self->cols );
    for my $row ( @{ $self->rows || [] } ) {
        $ascii->addRow( @{ $row } );
    }

    return $ascii->draw( undef, undef, [qw/| | - |/] );
}


1;

__END__